ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Comment créer un formulaire et un dataenvironement par programmation   



L'auteur

Mike Gagnon
Canada Canada
Membre Simple
# 0000000025
enregistré le 14/10/2004

Gagnon Mike
Pte Claire Quebec - Canada
de la société MCRG Software
Fiche personnelle


Note des membres
18/20
1 vote


Contributions > 02 - SCX : Formulaires

Comment créer un formulaire et un dataenvironement par programmation
# 0000000229
ajouté le 15/08/2005 14:28:41 et modifié le 13/04/2006
consulté 5064 fois
Niveau initié

Version(s) Foxpro :
VFP 9.0
VFP 8.0
VFP 7.0

Description

Un méthode de créer un formulaire et un dataenvironment par programmation.

Code source :
oForm = Createobject("form")
oForm.caption ="Un formulaire et son enviromement"
oForm.AddObject("oenv","de")
oForm.AddObject("command1","oButton")
oForm.command1.Visible = .T.
oForm.Show(1)
Define Class CUSTOMER As Cursor
  Alias = "CUSTOMER"
  CursorSource = "CUSTOMER"
  Database = Home()+"SAMPLES\DATA\TESTDATA.DBC"
Enddefine

Define Class ORDERS As Cursor
  Alias = "ORDERS"
  CursorSource = "ORDERS"
  Database = Home()+"SAMPLES\DATA\TESTDATA.DBC"
Enddefine

Define Class ORDITEMS As Cursor
  Alias = "ORDITEMS"
  CursorSource = "ORDITEMS"
  Database = Home()+"SAMPLES\DATA\TESTDATA.DBC"
Enddefine

Define Class Cust_To_Orders As Relation
  ChildAlias = "ORDERS"
  ParentAlias = "CUSTOMER"
  ChildOrder = "CUST_ID"
  RelationalExpr = "CUST_ID"
Enddefine

Define Class Orders_To_OrdItems As Relation
  ChildAlias = "ORDITEMS"
  ParentAlias = "ORDERS"
  ChildOrder = "ORDER_ID"
  RelationalExpr = "ORDER_ID"
Enddefine

Define Class DE As DataEnvironment
  Add Object oCUSTOMER             As CUSTOMER
  Add Object oORDERS               As ORDERS
  Add Object oORDITEMS             As ORDITEMS
  Add Object oCust_To_Orders       As Cust_To_Orders
  Add Object oOrders_To_OrdItems   As Orders_To_OrdItems

  Procedure Init
    This.OpenTables()
  Endproc

Enddefine
Define Class oButton As CommandButton
    Caption ="Ouvrir la table customer"
    height = 23
    width = 150
    top = 20
    left = 20
  Procedure Click
    Select CUSTOMER
    Browse
  Endproc
Enddefine


Commentaires
le 19/08/2005, Goupil a écrit :
Voila qui est clair,
Merci à Mike pour l'ensemble de son oeuvre!
Richard


Publicité

Les pubs en cours :

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2019.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3