ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Créer une liste ou une zone de liste déroulante dont on peut paramétrer le format item par item.   


L'auteur

Patrickl
Belgique Belgique
Membre Simple
# 0000000857
enregistré le 09/01/2006
64 ans
LEJEUNE Patrick
4800 Lambermont
Fiche personnelle

Note des membres
18/20
1 vote

Contributions > 20 - Trucs et Astuces

Créer une liste ou une zone de liste déroulante dont on peut paramétrer le format item par item.
# 0000000399
ajouté le 02/02/2007 07:23:16 et modifié le 02/02/2007
consulté 8970 fois
Niveau initié

Version(s) Foxpro :
VFP 9.0
VFP 8.0
VFP 7.0

Le téléchargement des pièces jointes est limité aux membres
Veuillez vous identifier ou vous inscrire si vous n'avez pas encore de compte ...
Description
Je me suis permis de m'inspirer d'un exemple de Mike Gagnon publié en 2004 et je l'ai complété afin de montrer comment paramétrer tous les attributs de formatage de chaque ligne de la liste ou de la zone de liste déroulante.
Code source :
CREATE CURSOR _test (cnom C(20), lpolice L(1))
FOR i = 1 TO 20
  INSERT INTO _test (cnom, ;
                     lpolice) ;
       VALUES ("Ceci est la ligne " + ALLTRIM(STR(i, 2 , 0)), ;
                IIF(MOD(i,2)= 0, .T., .F.))
ENDFOR
PUBLIC oform1
oform1=CREATEOBJECT("form1")
oform1.Show
RETURN
DEFINE CLASS form1 AS form
    Top = 0
    Left = 0
    Height = 238
    Width = 700
    DoCreate = .T.
    Caption = "Liste et zone de liste formatées"
    Name = "Form1"
   ADD OBJECT list1 AS combobox WITH ;
        RowSourceType = 9, ;
        RowSource = "P_list", ;
        Height = 24, ;
        Left = 60, ;
        Top = 24, ;
        Width = 265, ;
        Name = "List1"
   ADD OBJECT list2 AS listbox WITH ;
        RowSourceType = 9, ;
        RowSource = "P_list2", ;
        Height = 165, ;
        Left = 330, ;
        Top = 24, ;
        Width = 265, ;
        Name = "List2"
    PROCEDURE Load
        LOCAL nRec as Integer, cPolice as Character, ;
              cCouleur as Character, ;
              cIcone as Character
        nRec = 1
        cPolice = ""
        cIcone = ""
        PUBLIC P_list, P_list2
        DEFINE POPUP P_list
        DEFINE POPUP P_list2 SCROLL
        SELECT _test
        SCAN
          IF _test.lpolice
            cPolice = "'Comic sans MS',10 style 'BI'"
            cCouleur = "RGB(0,0,255,255,255,255)"
            cIcone = "C:\Programmes\...\BITMAPS\....ico"
          ELSE
            cPolice = "'Arial',10 style 'B'"
            cCouleur = "RGB(255,255,255,0,0,255)"
             cIcone = "C:\Programmes\...\BITMAPS\....ico"
         ENDIF
          *-* Pour remplir la zone de liste (listbox)
          DEFINE BAR nRec OF P_LIST ;
            PROMPT _test.cnom ;
            FONT &cPolice ;
            PICTURE cIcone ;
            COLOR , &cCouleur
          *-* Pour remplir la liste déroulante (combo)
          DEFINE BAR nRec OF P_LIST2 ;
            PROMPT _test.cnom ;
            FONT &cPolice ;
            PICTURE cIcone ;
            COLOR , &cCouleur
          nRec = nRec + 1
        ENDSCAN
    ENDPROC
Commentaires
Aucun commentaire enregistré ...
www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2024.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3