jeu. 23 septembre 2004, 09h55
Thierry Nivelet
atoutfox.public.association
Re: [Trucs et astuces]
Bonjour,
J'ai souvent vu le même principe utilisé pour garantir le rétablissement de l'environnement à la
sortie (accidentelle) d'un module
Par exemple un SET :
* ===================================
?
? Set('exact')
LOCAL loSet
loSet = CreateObject('cusSetOnOff', 'EXACT', 'ON')
? Set('exact')
RELEASE loSet
? Set('exact')
loSet = CreateObject('cusSetOnOff', 'EXACT', 'toto')
* ===================================
DEFINE CLASS cusSetOnOff as Custom
SetType = .F.
ValueOld = .F.
* --------------------------------------
PROCEDURE INIT
LPARAMETERS tcSet, tcValue
LOCAL llResult
* Si les paramètres sont en caractères
IF Vartype(m.tcSet) == 'C' ;
AND Vartype(m.tcValue) == 'C'
m.tcSet = Upper(Alltrim(m.tcSet))
m.tcValue = Upper(Alltrim(m.tcValue))
* Si les paramètres ont des valeurs correctes
LOCAL lcSetCheck
m.lcSetCheck = 'set("' + m.tcSet + '")'
IF Type(m.lcSetCheck) == 'C'; && le set est reconnu par VFP
AND InList(Evaluate(m.lcSetCheck), 'ON', 'OFF') ; && la valeur actuelle du set est OK
AND InList(m.tcValue, 'ON', 'OFF') && la valeur demandée est OK
* Mémoriser les valeurs actuelles
this.SetType = m.tcSet
this.ValueOld = set(m.tcSet)
* Appliquer les nouvelles valeurs
SET &tcSet &tcValue
m.llResult = .T.
ENDIF
ENDIF
ASSERT m.llResult MESSAGE "La Classe cusSetOnOff ne peut être instanciée avec ces paramètres : " + ;
+ Transform(m.tcSet) + ', ' + Transform(m.tcValue)
RETURN m.llResult
* --------------------------------------
PROCEDURE DESTROY
LOCAL lcSet, lcValue
m.lcSet = this.SetType
m.lcValue = this.ValueOld
* Si des valeurs correctes sont mémorisées
&& (devrait toujours être vrai)
IF Vartype(m.lcSet) == 'C';
AND Vartype(m.lcValue) == 'C'
* Appliquer !
SET &lcSet &lcValue
ENDIF
ENDDEFINE
* ===================================
--
AtoutFoxement,
Th Nivelet
Communauté Francophone des Professionnels FoxPro
news://news.AtoutFox.com/AtoutFox.association
"Thierry" <tper_NOSPAM@vfemail.net> a écrit dans le message de news:e6JmjeMoEHA.2000@serveur...
> Voici ma petite contribution :
>
> Beaucoup d'entre nous, ont déjà eu des petites difficultés lors d'un
> débogage d'un prog utilisant des fopen() ou fcreate().
> Quand il plante au milieu, on le relance mais le fichier est déjà ouvert, et
> on n'a alors que CLOSE ALL pour le fermer car on ne connait plus le n°
> "handle" du fichier.
>
> * Exemple : à lancer 2 fois !
>
> Local handle
> handle = fCreate("c:\log1.txt")
> IF handle <0
> ? "Impossible de créer le fichier"
> ELSE
> ? "Fichier créé"
> ENDIF
> CANCEL
> fClose(handle)
>
> * Voici une version guère plus compliqué, et qui vous simplifie le débogage.
>
> LOCAL oHandle
> oHandle = NewObject("handle")
> oHandle.h=fCreate("c:\log2.txt")
> IF oHandle.h <0
> ? "Impossible de créer le fichier"
> ELSE
> ? "Fichier créé"
> ENDIF
> CANCEL
> fClose(oHandle.h)
>
> DEFINE CLASS Handle as Custom
> h = 0
> PROCEDURE destroy
> fClose(this.h)
> ENDPROC
> ENDDEFINE
>
> Dès que la variable locale "oHandle" sera détruite, l'événement Destroy sera
> déclenché, fermant ainsi le fichier.
>
> --
> Thierry
>
>
> "Christophe CHENAVIER" <c.chenavier_@_corwin.fr> a écrit dans le message de
> news: xZzzXe6nEHA.1400@serveur...
> > Comme vous l'avez peut-être lu dans le programme de la rencontre de
> > novembre, j'ai l'honneur et l'avantage d'animer la rubrique Trucs et
> > Astuces.
> > Cette rubrique n'est pas l'apanage d'une seule personne, mais bien entendu
> > de toutes celles et ceux qui ont une quelque chose à dire à ce sujet.
> > Je me propose donc de présenter une synthèse de toutes les remarques que
> > vous voudrez bien faire ici.
> > Toutes ces astuces pourront être répertoriées par la suite sur le site web
> > de l'association.
> >
> > A vos claviers,
> >
> > --
> > AtoutFoxement,
> > C.Chenavier
> > Communauté Francophone des Professionnels FoxPro
> > news://news.atoutfox.org/atoutfox.association
> > --
> >
> >
>
>
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000000604