sam. 23 avril 2011, 10h20
Gregory
atoutfox.public.association
Re: Combo et multi colonne
Oui, sauf que le nom est ...cbolistbad
______
Gregory
______
"OlivierH" wrote in message news:iou0gp$p35$1@news.niouzes.net...
Pas mal vu, sauf que le foutu exemple de ms il est au debut
PUBLIC ofrmListExamples
ofrmListExamples=NEWOBJECT("frmListExamples")
ofrmListExamples.Show
RETURN
DEFINE CLASS frmListExamples AS form
DataSession = 2
Top = 0
Left = 0
Height = 262
Width = 325
Caption = "List and ListItem Array Example"
Name = "frmListExamples"
ADD OBJECT shape1 AS shape WITH ;
Top = 43, ;
Left = 32, ;
Height = 76, ;
Width = 261, ;
SpecialEffect = 0, ;
Name = "Shape1"
ADD OBJECT cbolistbad AS combobox WITH ;
ColumnCount = 3, ;
ColumnWidths = "100,100,50", ;
Height = 22, ;
Left = 111, ;
Sorted = .T., ;
Style = 2, ;
TabIndex = 1, ;
Top = 53, ;
Width = 147, ;
Name = "cboListBad"
ADD OBJECT cbolistitem AS combobox WITH ;
ColumnCount = 3, ;
ColumnWidths = "100,100,50", ;
Left = 34, ;
Sorted = .T., ;
Style = 2, ;
TabIndex = 3, ;
Top = 154, ;
Name = "cboListItem"
ADD OBJECT label1 AS label WITH ;
FontBold = .T., ;
Caption = "Using the List Array:", ;
Height = 17, ;
Left = 34, ;
Top = 24, ;
Width = 176, ;
TabIndex = 7, ;
Name = "Label1"
ADD OBJECT label2 AS label WITH ;
FontBold = .T., ;
Caption = "Using the ListItem Array:", ;
Height = 17, ;
Left = 34, ;
Top = 135, ;
Width = 173, ;
TabIndex = 8, ;
Name = "Label2"
ADD OBJECT cbolistgood AS combobox WITH ;
ColumnCount = 3, ;
ColumnWidths = "100,100,50", ;
Height = 22, ;
Left = 111, ;
Sorted = .T., ;
style = 2, ;
TabIndex = 2, ;
Top = 86, ;
Width = 147, ;
Name = "cboListGood"
ADD OBJECT label3 AS label WITH ;
Alignment = 1, ;
Caption = "Wrong!", ;
Height = 17, ;
Left = 51, ;
Top = 56, ;
Width = 47, ;
TabIndex = 9, ;
Name = "Label3"
ADD OBJECT label4 AS label WITH ;
Alignment = 1, ;
Caption = "Right!", ;
Height = 17, ;
Left = 58, ;
Top = 89, ;
Width = 40, ;
TabIndex = 10, ;
Name = "Label4"
PROCEDURE cbolistbad.Init
WITH This
.AddItem( 'Cleveland' )
.AddItem( 'Ohio', .NewIndex, 2 )
.AddItem( '44122', .NewIndex, 3 )
.AddItem( 'Caversham' )
.AddItem( 'England', .NewIndex, 2 )
.AddItem( 'RG4 8BX', .NewIndex, 3 )
.AddItem( 'Buffalo' )
.AddItem( 'New York', .NewIndex, 2 )
.AddItem( '14228', .NewIndex, 3 )
.AddItem( 'Milwaukee' )
.AddItem( 'Wisconsin', .NewIndex, 2 )
.AddItem( '43225', .NewIndex, 3 )
.AddItem( 'International Falls')
.AddItem( 'Minnesota', .NewIndex, 2 )
.AddItem( '42666', .NewIndex, 3 )
ENDWITH
ENDPROC
PROCEDURE cbolistgood.Init
WITH This
.AddItem( 'Cleveland' )
.List[.NewIndex, 2] = 'Ohio'
.List[.NewIndex, 3] = '44122'
.AddItem( 'Caversham' )
.List[.NewIndex, 2] = 'England'
.List[.NewIndex, 3] = 'RG4 8BX'
.AddItem( 'Buffalo' )
.List[.NewIndex, 2] = 'New York'
.List[.NewIndex, 3] = '14228'
.AddItem( 'Milwaukee' )
.List[.NewIndex, 2] = 'Wisconsin'
.List[.NewIndex, 3] = '43225'
.AddItem( 'International Falls' )
.List[.NewIndex, 2] = 'Minnesota'
.List[.NewIndex, 3] = '42666'
ENDWITH
ENDPROC
PROCEDURE cbolistitem.Init
WITH This
.AddListitem( 'Cleveland' )
.AddListItem( 'Ohio', .NewItemID, 2 )
.AddListItem( '44122', .NewItemID, 3 )
.AddListItem( 'Caversham' )
.AddListItem( 'England', .NewItemID, 2 )
.AddListItem( 'RG4 8BX', .NewItemID, 3 )
.AddListItem( 'Buffalo' )
.AddListItem( 'New York', .NewItemID, 2 )
.AddListItem( '14228', .NewItemID, 3 )
.AddListItem( 'Milwaukee' )
.AddListItem( 'Wisconsin', .NewItemID, 2 )
.AddListItem( '43225', .NewItemID, 3 )
.AddListItem( 'International Falls')
.AddListItem( 'Minnesota', .NewItemID, 2 )
.AddListItem( '42666', .NewItemID, 3 )
ENDWITH
ENDPROC
ENDDEFINE
OLivier
Le 22/04/11 20:30, Gregory a écrit :
>> les lignes ne vont pas bien,
>
> (1) Tu as modifie l'exemple de l'aide
> (2) Si tu lis bien l'aide tu verras qu'il faut mettre Sorted = .t. APRES
> l'ajout des items
>
>
>
> this.ColumnCount = 3
> this.ColumnWidths = "100,100,50"
>
> =Dodefault()
>
> with m.this
> .AddListItem( 'Cleveland' )
> .AddListItem( 'Ohio', .NewIndex, 2 )
> .AddListItem( '44122', .NewIndex, 3 )
>
> .AddListItem( 'Caversham' )
> .AddListItem( 'England', .NewIndex, 2 )
> .AddListItem( 'RG4 8BX', .NewIndex, 3 )
>
> .AddListItem( 'Buffalo' )
> .AddListItem( 'New York', .NewIndex, 2 )
> .AddListItem( '14228', .NewIndex, 3 )
>
> .AddListItem( 'Milwaukee' )
> .AddListItem( 'Wisconsin', .NewIndex, 2 )
> .AddListItem( '43225', .NewIndex, 3 )
>
> .AddListItem( 'International Falls')
> .AddListItem( 'Minnesota', .NewIndex, 2 )
> .AddListItem( '42666', .NewIndex, 3 )
>
> endwith
> this.Sorted = .t.
>
>
>
> ______
> Gregory
> ______
> "OlivierH" wrote in message news:iosfre$29dm$1@news.niouzes.net...
>
> meme en prenant l'example de vfp
>
> les lignes ne vont pas bien,
>
>
>
> WITH This
> .ColumnCount = 3
> .ColumnWidths = "100,100,50"
> .Sorted = .T.
>
> .AddItem( 'Cleveland' )
> .AddItem( 'Ohio', .NewIndex, 2 )
> .AddItem( '44122', .NewIndex, 3 )
> .AddItem( 'Caversham' )
> .AddItem( 'England', .NewIndex, 2 )
> .AddItem( 'RG4 8BX', .NewIndex, 3 )
> .AddItem( 'Buffalo' )
> .AddItem( 'New York', .NewIndex, 2 )
> .AddItem( '14228', .NewIndex, 3 )
> .AddItem( 'Milwaukee' )
> .AddItem( 'Wisconsin', .NewIndex, 2 )
> .AddItem( '43225', .NewIndex, 3 )
> .AddItem( 'International Falls')
> .AddItem( 'Minnesota', .NewIndex, 2 )
> .AddItem( '42666', .NewIndex, 3 )
> ENDWITH
>
> Est ce que cela fait ca chez toi ?
>
> Olivier,
>
>
> Le 22/04/2011 19:49, OlivierH a écrit :
>> Greg,
>>
>> Tu peux m'expliquer cette effet imcompréhensible.
>>
>>
>> ThisForm.Combo1.ColumnLines= .T.
>> ThisForm.Combo1.ColumnCount = 3
>> ThisForm.combo1.ColumnWidths ="150,150,150"
>>
>>
>> ThisForm.Combo1.AddItem("colonne 1 i=1",1,1)
>> ThisForm.Combo1.AddItem("colonne 2 i=1",1,2)
>> ThisForm.Combo1.AddItem("colonne 3 i=1",1,3)
>> ThisForm.Combo1.picture(1) = "images\mini_etoile1.bmp"
>>
>> ThisForm.Combo1.AddItem("colonne 1 i=2",2,1)
>> ThisForm.Combo1.AddItem("colonne 2 i=2",2,2)
>> ThisForm.Combo1.AddItem("colonne 3 i=2",2,3)
>> ThisForm.Combo1.picture(2) = "images\mini_etoile2.bmp"
>>
>>
>> ThisForm.Combo1.AddItem("colonne 1 i=3",3,1)
>> ThisForm.Combo1.AddItem("colonne 2 i=3",3,2)
>> ThisForm.Combo1.AddItem("colonne 3 i=3",3,3)
>> ThisForm.Combo1.picture(3) = "images\mini_etoile3.bmp"
>>
>> Olivier
>>
>>
>> Le 22/04/2011 19:39, OlivierH a écrit :
>>> Hello Greg,
>>>
>>> J'etais sur cette voie mais pas du tout pour les lignes,
>>> j'arrive bien pour les colonnes mais tu me mets un doute pour les Row.
>>>
>>> As tu pu le faire pour les Row ?
>>>
>>> cdlt
>>> Olivier,
>>>
>>>
>>> Le 22/04/2011 19:26, Gregory a écrit :
>>>>
>>>> ThisForm.Combo1.AddItem("first item",1)
>>>> ThisForm.Combo1.picture(1) = 'C:\GRAPHICS\firstImg.BMP'
>>>> ThisForm.Combo1.AddItem("second item",2)
>>>> ThisForm.Combo1.picture(2) = 'C:\GRAPHICS\secondImg.GIF'
>>>>
>>>> ThisForm.Combo1.AddItem("last item",3)
>>>> ThisForm.Combo1.picture(3) = 'C:\GRAPHICS\myIcon.ico'
>
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000005627