ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Aligner du texte en   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

dim. 05 juin 2011, 14h24

Francis Faure
France France

atoutfox.public.association

Re: Aligner du texte en <Colonne>

Bonjour JPG,

En ce jour de printemps très pluvieux :
J'ai essayé de répliquer ton problème au sujet de ta question de tabulations
avec un petit programme et au moyen des éléments que tu as communiqué ci-avant :

mais
Chez moi cela fonctionne très bien (pc : Windows 7 VFP9SP2 Hotfix 3)
je ne constate pas de problème... !

donc,
Voici le programme que j'ai fais pour répliquer
(que ce soit en 80 ou 90 cela fonctionne très bien)

Pourrais tu copier/coller ce programme en dehors de tes programmes et vérifier que c'est ok aussi
si c'est le cas : il y a autre chose dans tes prog qui provoque le problème
sinon c'est que tu n'est pas en VFP9SP2 HF3


oJPG=Createobject("form1")
oJPG.Show()
Read Events
Release oJPG


Define Class form1 As Form
  Top = 0
  Left = 0
  Height = 326
  Width = 589
  DoCreate = .T.
  Caption = "Test Tabulations pour JPG"
  Name = "Form1"

  Add Object edit1 As EditBox With ;
    FontName = "Arial", ;
    FontSize = 9, ;
    Anchor = 15, ;
    AllowTabs = .T., ;
    Height = 264, ;
    Left = 12, ;
    TabIndex = 1, ;
    Top = 12, ;
    Width = 564, ;
    Name = "Edit1"

  Add Object bok As CommandButton With ;
    Top = 288, ;
    Left = 492, ;
    Height = 27, ;
    Width = 84, ;
    Anchor = 12, ;
    Cancel = .T., ;
    Caption = "Ok", ;
    Default = .T., ;
    TabIndex = 3, ;
    Name = "bOk"

  Add Object breport As CommandButton With ;
    Top = 288, ;
    Left = 12, ;
    Height = 27, ;
    Width = 84, ;
    Anchor = 6, ;
    Caption = "Report", ;
    TabIndex = 2, ;
    Name = "bReport"

  Procedure edit1.Init
    This.Value = "RDC"+Chr(9)+Chr(9)+": 128 m²"+Chr(13)+Chr(10)+;
      "1er étage"+Chr(9)+": 234 m²"+Chr(13)+Chr(10)+;
      "S/SOL"+Chr(9)+Chr(9)+": 74 m²"+Chr(13)+Chr(10)+;
      "S"+Chr(9)+Chr(9)+Chr(9)+": 100 m²"+Chr(13)+Chr(10)+;
      CHR(13)+Chr(10)+;
      CHR(9)+"Montant H.T.:"+Chr(9)+"100.00"+Chr(13)+Chr(10)+;
      CHR(9)+"TVA :"+Chr(9)+"19.6%"+Chr(9)+" 19.60"+Chr(13)+Chr(10)+;
      CHR(9)+Chr(9)+Chr(9)+Chr(9)+Chr(9)+"----------"+Chr(13)+Chr(10)+;
      CHR(9)+"Montant TTC :"+Chr(9)+"119.60"+Chr(13)+Chr(10)
  Endproc

  Procedure bok.Click
    Thisform.Release()
    Clear Events
  Endproc

  Procedure breport.Click
    Create Cursor cursortabs (mymemo m)
    Insert Into cursortabs (mymemo) Values (Thisform.edit1.Value)

    * création d'un rapport de test
    Set Safety Off
    Create Report cursortabs From cursortabs Form Fields mymemo
    * le champ mémo en Arial, 9, Normal, largeur
    Use cursortabs.frx In 0 Alias "ReportTest"
    Update cursortabs.frx Set Width=66000, FontFace="Arial", FontSize=9, FontStyle=0, Stretch=.T. Where Objtype=8 And Expr="mymemo"
    Use In "ReportTest"

    * test en 80
    Set REPORTBEHAVIOR 80
    Report Form cursortabs Preview

    * test en 90 et mode listener
    Set REPORTBEHAVIOR 90
    o=Newobject("ReportListener", Home()+"ffc\_reportlistener.vcx")
    o.ListenerType=1
    Report Form cursortabs Object o
    o=Null

    Use In "cursortabs"
  Endproc

Enddefine



peut être est-ce que j'utilise la version actuelle de vfp
car je vois une mention relative au chr(9) dans le fichier d'aide :
HELP Changes in Functionality for the Current Release


Quelle est la version de VFP que tu utilises ?

ou je n'ai pas compris ?

Cordialement
Francis FAURE

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000006069
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3