ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Gestion des erreurs dans un objet par événement Error   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

ven. 24 juin 2011, 13h40

Francis Faure
France France

atoutfox.public.association

Re: Gestion des erreurs dans un objet par événement Error

Bonjour Luc,

Je pense qu'il y a plein de solutions, je te fais 4 propositions :

Dans le code change le
#Define PROPOSITION
en tête de l'exemple

Cordialement
Francis


#Define PROPOSITION 1


* Test : erreur sur objet instancié sur la classe "pere"
Local lo As Object
lo = Createobject("cObjectError_Base")
m.lo.GénèreErreur()
Release lo

* Erreur sur objet instancié sur la classe "fille"
Local lo As cObjectError
lo = Createobject("cObjectError")
m.lo.GénèreErreur()
Release lo



#If PROPOSITION=1

* Gestion dans la classe de base en fonction du nom de la Classe
Define Class cObjectError As cObjectError_Base
Enddefine
Define Class cObjectError_Base As Collection
  Procedure GénèreErreur()
    FonctionQuiNExistePas()
  Endproc
  Procedure Error(nError, cMethod, nLine)
    If Upper(This.Class)==Upper("cObjectError_Base")
      Messagebox("Gestion Erreur Interne")
    Else
      Messagebox("Gestion Erreur vfp")
      Error m.nError, Message(1)+" dans la méthode "+m.cMethod
    Endif
  Endproc
Enddefine

#Endif



#If PROPOSITION=2

* Gestion d'erreur surchargée dans la classe fille
Define Class cObjectError As cObjectError_Base
  Procedure Error(nError, cMethod, nLine)
    Error m.nError, Message(1)
  Endproc
Enddefine
Define Class cObjectError_Base As Collection
  Procedure GénèreErreur()
    FonctionQuiNExistePas()
  Endproc
  Procedure Error(nError, cMethod, nLine)
    Messagebox("Gestion Erreur Interne")
  Endproc
Enddefine

#Endif




#If PROPOSITION=3

* Gestion d'erreur surchargée dans la classe fille appelant un parametre de la gestion d'erreur de la classe de base
Define Class cObjectError As cObjectError_Base
  Procedure Error(nError, cMethod, nLine)
    DoDefault(m.nError, m.cMethod, m.nLine, .T.)
  Endproc
Enddefine
Define Class cObjectError_Base As Collection
  Function GénèreErreur()
    FonctionQuiNExistePas()
  Endfunc
  Procedure Error(nError, cMethod, nLine, lDefaultError)
    If m.lDefaultError
      Messagebox("Gestion Erreur vfp ")
      Error Message()
    Else
      Messagebox("Gestion Erreur Interne")
    Endif
  Endproc
Enddefine

#Endif



#If PROPOSITION=4

* Gestion d'erreur surchargée dans la classe fille appelant une autre méthode de la classe de base
Define Class cObjectError As cObjectError_Base
  Procedure Error(nError, cMethod, nLine)
    cObjectError_Base::NormalError(nError, cMethod, nLine)
  Endproc
Enddefine
Define Class cObjectError_Base As Collection
  Function GénèreErreur()
    FonctionQuiNExistePas()
  Endfunc
  Procedure Error(nError, cMethod, nLine)
      Messagebox("Gestion Erreur Interne")
  Endproc
  Procedure NormalError(nError, cMethod, nLine)
      Messagebox("Gestion Erreur vfp ")
      ERROR MESSAGE()
  Endproc
Enddefine

#Endif



Permalink : http://www.atoutfox.org/nntp.asp?ID=0000006263
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3