ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Gestion des erreurs dans un objet par événement Error   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

jeu. 30 juin 2011, 09h12

Luc
France France

atoutfox.public.association

Re: Gestion des erreurs dans un objet par événement Error

Salut
Voici un exemple plus complet pour illustrer le problème. Mais c'est juste pour info car j'ai finalement abandonné ...

A +

Luc

Public gcLog
m.gcLog = ""
Local lo1, lo2, lo3, lcOnError

* Mise en place de l'erreur VFP
m.lcOnError = On("Error")
On Error m.gcLog = m.gcLog + "Erreur VFP via On Error"

* Premier cas : l'erreur est gérée par le On Error de VFP
m.gcLog = m.gcLog + "Premier cas : l'erreur est gérée par le On Error de VFP : "
lo1 = CreateObject("cTesteErreur1")
lo1.Plante()

* Second cas : l'erreur est gérée par l'événement Error de l'objet
m.gcLog = m.gcLog + Chr(13) + "Second cas : l'erreur est gérée par l'événement Error de l'objet : "
lo2 = CreateObject("cTesteErreur2")
lo2.Plante()

* Troisième cas : l'erreur est gérée par l'événement Error de l'objet
m.gcLog = m.gcLog + Chr(13) + "Troisième cas : l'erreur est gérée par l'événement Error de l'objet : "
lo3 = CreateObject("cTesteErreur3")
lo3.Plante()

* Quatrième cas : l'erreur est gérée par l'événement Error de l'objet et est ramené à l'erreur de la classe mère
m.gcLog = m.gcLog + Chr(13) + "Quatrième cas : l'erreur est gérée par l'événement Error de l'objet et est ramené à l'erreur de la classe MERE : "
lo4 = CreateObject("cTesteErreur4")
lo4.Plante()

* Cinquième cas : l'erreur est gérée par l'événement Error de l'objet et est ramené à l'erreur de la classe de base
m.gcLog = m.gcLog + Chr(13) + "QCinquième cas : l'erreur est gérée par l'événement Error de l'objet et est ramené à l'erreur de la classe DE BASE : " ;
              + Chr(13) + " Dans ce cas, rien ne se passe : aucue erreur n'est attrapée"
lo4 = CreateObject("cTesteErreur3")
lo4.lUseCustomError = .T.
lo4.Plante()

* Restaurer l'erreur VFP initiale
On Error &lcOnError

* Afficher le résultat
MessageBox(m.gcLog)

* -----------------------------------------------------------------------------------------------------------------------------------------------------------
Define Class cTesteErreur1 as Relation
  Function Plante
    &Erreur
  EndFunc
Enddefine

* -----------------------------------------------------------------------------------------------------------------------------------------------------------
Define Class cTesteErreur2 as cTesteErreur1
  Function Error
    LPARAMETERS nError, cMethod, nLine
    m.gcLog = m.gcLog + "Erreur dans la classe cTesteErreur2"
  EndFunc
Enddefine

* -----------------------------------------------------------------------------------------------------------------------------------------------------------
Define Class cTesteErreur3 as cTesteErreur2
  lUseParentClassError = .F.
  lUseBaseClassError = .F.
  Function Error
    LPARAMETERS nError, cMethod, nLine

    Do case
      Case This.lUseBaseClassError
        * Gestion d'erreur de la classe parente
        Relation::Error(nError, cMethod, nLine)

      Case This.lUseParentClassError
        * Gestion d'erreur de la classe mère
        DoDefault(nError, cMethod, nLine)

      Otherwise
        * Gestion d'erreur personnalisée
        m.gcLog = m.gcLog + "Erreur dans la classe cTesteErreur3"

    Endcase

  EndFunc
Enddefine

* -----------------------------------------------------------------------------------------------------------------------------------------------------------
Define Class cTesteErreur4 as cTesteErreur3
  lUseParentClassError = .T.
  lUseBaseClassError = .F.
Enddefine

* -----------------------------------------------------------------------------------------------------------------------------------------------------------
Define Class cTesteErreur5 as cTesteErreur3
  lUseParentClassError = .F.
  lUseBaseClassError = .T.
Enddefine


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000006305
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3