ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: PostGres   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

ven. 05 août 2011, 19h00

GLS
France France

atoutfox.public.association

Re: PostGres

Bonjour Michel

as-tu essayé la version actuelle de PostGreSql 9.32 de mémoire, parce qu'a part le filestreaming, et le changement de contexte d'exécution a l'intérieure d'une même connexion, pour tout le reste il y a des solutions ou des équivalences avec des applications tierces à PostGresql..

maintenant pour les as de la programmation en transact SQL n'utilisant que très peu les outils de gestion de données de VFP, ou pour ceux voulant utiliser un environnement .NET, ce n'est pas PostGreSql vers lequel il faut se tourner..

pour tous les autres,je peux dire qu'après mes nombreux tests et échecs d'installations des différentes versions de m$ SQL SERVER avec leurs déboires et lourdeurs, je dirais grossièrement qu'il n'y a pas photo, ceux qui veulent du simple et du facile c'est PostGreSql qui est le grand gagnant. Une installation en moins de 10mn sans avoir besoin de tous les machins de m$ (.NET,etc..).

Enfin si vous utilisez la gestion et le traitement des données sous VFP et que vous contentez de vues distantes, de requêtes SQL dans des curseurs, PostGreSql est très largement suffisant apportant toutes les réponses liés aux problèmes d'utilisation des DBF (pertes des index en cas de mauvais fonctionnement de la couche réseau, limite des tables à 2G0, pas de sauvegarde à chaux, faux fonctionnement client/serveur). Il faut juste traiter correctement le mappage des champs logique VFP en champ Smallint de PostGres si l'on utilise des vues et des cases à cocher liées a ces vues.
Pour la gestion des données PGADMIN permet d''accéder aux données de créer et manager des bases et bien sur de requeter les tables comme avec une simple command browse de VFP..

ci après une bonne base de travail pour exporter des tables DBF vers PostGreSql

* Francis Faure
* 9/7/2006
* Dump Dbf->Sql
* but: générer un fichier texte pour importation dans PostGresSql
* a vérifier : les types et a tester...
* v1.1 du 10/07/2006 !: gestion des binary, date, numérique
* Ne gére pas les champs de type "GENERAL"
* adapté GLS 06/2011

CLEAR
SET DATE FRENCH
SET CENTURY ON
CLEAR ALL


LOCAL ls_import_PostGresSql_vfp_data_file AS STRING, cPrimaryKey AS STRING , cTable AS STRING , iCount AS INTEGER, cCheminData AS STRING, cBase AS STRING
LOCAL t_table[2]
m.cCheminData="d:\tablevfp\"
m.cBase="mabase"

ls_import_PostGresSql_vfp_data_file = m.cCheminData+"datatable_"+m.cBase+".sql"
IF FILE(ls_import_PostGresSql_vfp_data_file)
  DELETE FILE (ls_import_PostGresSql_vfp_data_file)
ENDIF

t_table[1]="tabledbf1"
t_table[2]="tabledbf2"
OPEN DATABASE (m.cCheminData+m.cBase+'.dbc')
FOR m.iCount=1 TO ALEN(t_table)
  m.cTable=LOWER(t_table[m.iCount])
  IF !EMPTY(m.cTable) AND FILE(m.cCheminData+m.cTable+".dbf")
    USE (m.cCheminData+m.cTable+".dbf")
    m.cPrimaryKey=DBGETPROP(JUSTFNAME(m.cTable),"TABLE","PrimaryKey")
    =a_insert(JUSTFNAME(m.cTable), m.cPrimaryKey,ls_import_PostGresSql_vfp_data_file,.T.)
    USE
  ENDIF
ENDFOR
CLOSE DATABASES ALL

* fichier a incoporer dans le gestionnaire de base de données
*MODIFY COMMAND (ls_import_PostGresSql_vfp_data_file)

RETURN


FUNCTION Transformer(t_champ, tl_en_binaire) AS STRING
  LOCAL ls_return AS STRING
  LOCAL li_i
  IF ISNULL(t_champ)
    ls_return = "NULL"
  ELSE
    DO CASE
      CASE tl_en_binaire
        * cas du binaire a transformer en hexadecimal
        IF LEN(t_champ)>1
          ls_return = "0x"
          FOR li_i=1 TO LEN(t_champ)
            ls_return = ls_return + RIGHT(TRANSFORM( ASC(SUBSTR(t_champ,li_i,1)), "@0"),2)
          NEXT
        ELSE
          ls_return = "''"
        ENDIF
      CASE TYPE("t_champ")$"CMV"
        ls_return = ALLTRIM(t_champ)
        ls_return = STRTRAN(ls_return, CHR(92), CHR(92)+CHR(92)) && \ en \\
        ls_return = STRTRAN(ls_return, CHR(39), CHR(39)+CHR(39)) && ' en ''
        *        ls_return = STRTRAN(ls_return, CHR(39), CHR(92)+CHR(39)) && ' en \'
        ls_return = "'"+ls_return+"'"
      CASE TYPE("t_champ")$"YBFI"
        ls_return = ALLTRIM(STR(t_champ))
      CASE TYPE("t_champ")$"N"
        ls_return = ALLTRIM(STR(t_champ,12,2))
      CASE TYPE("t_champ")=="D"
        ls_return = "'" + LEFT(TTOC(t_champ,3),10) + "'"
      CASE TYPE("t_champ")=="T"
        ls_return = "'" + TTOC(t_champ,3) + "'"
      CASE TYPE("t_champ")=="L"
        * boolean .T. = 1
        IF t_champ
          ls_return = "1"
        ELSE
          ls_return = "0"
        ENDIF
      CASE TYPE("t_champ")=="Q"
        * cas particulier en binaire directement
        IF LEN(t_champ)>1
          ls_return = "0x" + TRANSFORM(t_champ)
        ELSE
          ls_return = "''"
        ENDIF
      OTHERWISE
        ls_return = "'?'"
        =MESSAGEBOX("a traiter Transformer type="+TYPE("t_champ"))
    ENDCASE
  ENDIF
  RETURN ls_return

FUNCTION a_insert(p_table AS STRING, p_clepk AS STRING, p_file AS STRING, p_append AS logical )
  LOCAL ARRAY la_Champs[1,18]
  LOCAL li_nombre_de_champs AS INTEGER
  LOCAL li_i AS INTEGER
  LOCAL c_sqlinsert AS STRING
  LOCAL ls_champ AS STRING
  LOCAL iRecno AS INTEGER, iCount AS INTEGER

  #DEFINE csCRLF CHR(13)+CHR(10)  && peut être " " c'est pour la lisibilité
  #DEFINE cs_delimiteur SPACE(0) && délimiteur champ de table
  #DEFINE cs_table CHR(34) &&" comme délimiteur nom de table

  IF EMPTY(ALIAS())
    =MESSAGEBOX("Import basesql impossible : pas de table en cours d'utilisation dans la zone active",16, "Dump Dbf2Sql")
    RETURN .F.
  ENDIF
  IF USED(p_table)
    SELECT (p_table)
    m.iRecno=RECCOUNT(p_table)
    m.iCount=0
    m.c_sqlinsert=""
    SCAN
      SELECT (p_table)
      m.iCount=m.iCount+1
      *IF !inactif
      WAIT "INSERT "+ALLTRIM(STR(m.iCount))+" sur "+ALLTRIM(STR(m.iRecno)) WINDOWS NOWAIT
      li_nombre_de_champs = AFIELDS(la_Champs)
      m.c_sqlinsert = m.c_sqlinsert+ 'INSERT INTO "'+LOWER(p_table)+'" ('+ csCRLF
      FOR li_i=1 TO li_nombre_de_champs
        IF la_Champs[li_i, 2]="G" OR IIF(!EMPTY(p_clepk),LOWER(la_Champs[li_i,1])=p_clepk,.F.) OR LOWER(la_Champs[li_i,1])="dateheure" OR LOWER(la_Champs[li_i,1])="inactif" && ignorer champ/colonne dateheure et inactif

        ELSE
          ls_champ = LOWER(la_Champs[li_i, 1])
          IF ls_champ='user'
            * Traitement du cas spécifique user qui doit être coté en SQL
            ls_champ='"'+ls_champ+'"'
          ENDIF
          m.c_sqlinsert = m.c_sqlinsert + SPACE(0)+ ls_champ + SPACE(0)
          m.c_sqlinsert = m.c_sqlinsert + ","
        ENDIF
      ENDFOR
      IF RIGHT(m.c_sqlinsert,1)=","
        * Suppression du dernier caractère si c'est ","
        m.c_sqlinsert=LEFT(m.c_sqlinsert,LEN(m.c_sqlinsert)-1)
      ENDIF
      m.c_sqlinsert = m.c_sqlinsert + ")" + csCRLF
      m.c_sqlinsert = m.c_sqlinsert + " VALUES ("
      FOR li_i=1 TO li_nombre_de_champs
        IF la_Champs[li_i, 2]="G" OR IIF(!EMPTY(p_clepk),LOWER(la_Champs[li_i,1])=p_clepk,.F.) OR LOWER(la_Champs[li_i,1])="dateheure" OR LOWER(la_Champs[li_i,1])="inactif" && ignorer champ/colonne dateheure et inactif

        ELSE
          ls_champ = EVALUATE(la_Champs[li_i, 1])
          IF la_Champs[li_i, 2]='D' OR la_Champs[li_i, 2]='T'
            IF EMPTY(ls_champ)
              ls_champ=.NULL.
            ENDIF
          ENDIF
          m.c_sqlinsert = m.c_sqlinsert + Transformer(ls_champ, la_Champs[li_i, 6])
          m.c_sqlinsert = m.c_sqlinsert + ","
        ENDIF
      ENDFOR

      IF RIGHT(m.c_sqlinsert,1)=","
        * Suppression du dernier caractère si c'est ","
        m.c_sqlinsert=LEFT(m.c_sqlinsert,LEN(m.c_sqlinsert)-1)
      ENDIF
      m.c_sqlinsert = m.c_sqlinsert + ");"+ csCRLF
      *ENDIF
    ENDSCAN
    m.c_sqlinsert = m.c_sqlinsert + csCRLF
  ENDIF
  =sqlemet(m.c_sqlinsert,'',.T.)
ENDFUNC

* Fonction d'émission des commandes SQL auprès du SGBDR
* Retourne -2 si action impossible ou erreur de connexion
* Retourne -1 si curseur p_curseur non créé ou si action sans curseur impossible
* retourne le nombre d'enregistrements du curseur p_curseur, ou le résultat de l'action sans curseur
FUNCTION sqlemet(p_Action,p_curseur,p_no_use_curseur)
  LOCAL iRetour, GnConnect, lcDSNLess
  m.iRetour=0
  * fermeture d'un éventuel curseur portant le même nom
  IF !p_no_use_curseur AND USED(p_curseur)
    USE IN SELECT(p_curseur)
  ENDIF

  * lcDSNLESS contient la chaine de connection au serveur SQL
  m.lcDSNLess="DRIVER = {SQL Server};" ;
    + "SERVER=<servername>;" ;
    + "UID=<userid>;" ;
    + "PWD=<password>;" ;
    + "DATABASE=PUBS;" ;
    + "WSID=<machine name or userid>;" ;
    + "APP=MicroX(R) Sample App"

  m.GnConnect=SQLSTRINGCONNECT(m.lcDSNLess,.T.)
  IF m.GnConnect > 0
    IF !p_no_use_curseur
      m.iRetour=SQLEXEC(m.GnConnect, p_Action,p_curseur)
    ELSE
      m.iRetour=SQLEXEC(m.GnConnect, p_Action)
    ENDIF
    DO CASE
      CASE !p_no_use_curseur AND m.iRetour=-1
        m.iRetour=-2
        =STRTOFILE("ERREUR exécution "+p_Action,"SqlErreur.txt",1)
      OTHERWISE
        IF !p_no_use_curseur AND USED(p_curseur)
          m.iRetour=RECCOUNT(p_curseur)
        ENDIF
    ENDCASE
    IF m.GnConnect>0
      SQLDISCONNECT(m.GnConnect)
    ENDIF
  ENDIF
  RETURN iRetour
ENDFUNC


Cordialement

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000006580
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3