ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Utiliser des mots réservés comme nom de variable   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

lun. 10 octobre 2011, 12h44

Francis Faure
France France

atoutfox.public.association

Re: Utiliser des mots réservés comme nom de variable

Sergejack,

Si je comprends bien ta question, tu veux faire quelque chose comme :

a) créer une classe olepublic (COM) qui lit des données VFP pour les stocker dans une propriété objet

#include FoxPro.H

Define Class myOcom As Session OlePublic

  nombre=Null
  Dimension Nombre_COMATTRIB[4]
  Nombre_COMATTRIB[1] = COMATTRIB_READONLY
  Nombre_COMATTRIB[2] = "Nombre pour exemple"
  Nombre_COMATTRIB[3] = "Nombre"
  Nombre_COMATTRIB[4] = "Integer"

  Data=Null
  Dimension Data_COMATTRIB[4]
  Data_COMATTRIB[1] = COMATTRIB_READONLY
  Data_COMATTRIB[2] = "Objet contenant un enregistrement"
  Data_COMATTRIB[3] = "Data"
  Data_COMATTRIB[4] = "Object"

  Function charge() As VOID
    Try
      Use Home(2)+"northwind\customers" Shared
      Go Top
      Scatter Memo Name This.Data
      This.nombre=1
      Use
    Catch
      This.nombre=0
    Endtry
  Endfunc

Enddefine


b) Compiler (attention a etre en mode adminsitrateur sur vista, windiws 7 ou 2008)
pour exposer au systeme

BUILD MTDLL myocom FROM myocom


c) consommer cette un objet instancié sur cette classe dans un autre VFP ou un autre programme ...

clear
o=Createobject("myOcom.myOcom")
? o.charge() && charge la premiere fiche client
? o.nombre && 1
If o.nombre>0
  ? o.Data.CustomerID
  ? o.Data.Companyname
  ? o.Data.ContactName
  ? o.Data.Country
Endif
o=null



Est-ce bien cela ta demande ?

Cordialement
Francis

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000007117
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3