ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Passage de parametre à une forme   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mar. 08 mai 2012, 10h40

GLS
France France

atoutfox.public.association

Re: Passage de parametre à une forme

* Pré requis
* 1) le formulaire doit être en session de donnée privée
* THISFORM.dataSession=2 && a mettre par DESIGN
* 2) la grille doit avoir le recordsourcetype sur alias
* thisform.grid1.recordsourcetype=1 && a mettre par DESIGN
* 3) la grille doit avoir le recordsource sur curconsultation
* thisform.grid1.recordsource="curconsultation" && a mettre par DESIGN le curseur dans le DESIGN n'a pas besoin d'être existant
* 4) la grille doit avoir le ColumnCount = nombre de colonne du curconsultation à afficher
* thisform.grid1.columncount=11 && a mettre par DESIGN le curseur dans le DESIGN n'a pas besoin d'être existant
* 5) les columns de la grille doivent avoir leur controlsource affecté avec une colonne du curseur curconsultation
* thisform.grid1.column1.controlsource="idetudeaf" && a mettre par DESIGN le curseur dans le DESIGN n'a pas besoin d'être existant
* thisform.grid1.column2.controlsource="nom" && a mettre par DESIGN le curseur dans le DESIGN n'a pas besoin d'être existant
* etc..


* Code à mettre dans l'évènement LOAD() du formulaire
=THISFORM.creationcurseur()
* Le DODEFAULT() est nécessaire à FoxInCloud pour traiter correctement le LOAD() du formulaire
DODEFAULT()


* Code à mettre dans une méthode CREATIONCURSEUR() ajoutée par DESIGN au formulaire
* Fermeture d'un éventuel curseur qui porterai ce nom si cette méthode est appelée plusieurs fois
IF USED('curconsultation')
  USE IN SELECT('curconsultation')
ENDIF
* Création d'un curseur vide curconsultation
CREATE CURSOR curconsultation (idetudeaf I, nom c(30) NOT NULL, prenom c(30) NULL, dnaissance d NULL,;
  numccp c(10) NULL, cleccp c(2) NULL, periode c(20) NULL,montant N(12,2) NULL,rappel N(12,2) NULL, retenue N(12,2) NULL, dpaiement d NULL)


* Code à mettre dans la méthode MAJCURSEUR() ajoutée par DESIGN au formulaire
LPARAMETERS p_netude
IF VARTYPE(p_netude)='N'
  LOCAL cValue
  * On va faire plaisir à Jean
  m.cValue= "SELECT a.idetudeaf, a.nom, a.prenom, a.dnaissance, a.numccp, a.cleccp, "+;
    "b.periode, b.montant, b.rappel, b.retenue, b.dpaiement "+;
    "FROM ebw002 a INNER JOIN ebw111 b ON a.idetudeaf = b.idetudemt "+;
    "WHERE a.idetudeaf = "+ALLTRIM(STR(p_netude)) && modification a faire plutôt que ? p_netude
  IF SQLEXEC(_SCREEN.conpgsql,m.cValue,'c_sql')<0
    =AERROR(errselect)
    =MESSAGEBOX("ERREUR Ouverture de la vue" + CHR(13) + "code erreur : "+STR(errselect[1])+CHR(13)+errselect[2],0+16+0,_SCREEN.titreforme)
    RELEASE errselect
  ELSE
    IF USED('curconsultation')
      SELECT curconsultation
      ZAP IN SELECT('curconsultation')
      APPEND FROM DBF('c_sql')
      * Remonte dans le haut de la grille pour l'affichage
      LOCATE
    ENDIF
    USE IN SELECT('c_sql')
    * Rafraichissement de la grille
    =THISFORM.grid1.REFRESH()
  ENDIF
ENDIF


* Code à mettre dans l'évènement DESTROY() du formulaire
IF USED('curconsultation')
  USE IN SELECT('curconsultation')
ENDIF
* Le DODEFAULT() est nécessaire à FoxInCloud pour traiter correctement le DESTROY() du formulaire
DODEFAULT()


* Code à mettre dans l'évènement INIT() du formulaire
LPARAMETERS p_netude
* Le DODEFAULT() est nécessaire à FoxInCloud pour traiter correctement l'INIT() du formulaire
DODEFAULT()
IF PCOUNT()>0
   =THISFORM.majcursor(p_netude)
ENDIF
&&&&&
*WAIT WINDOW 'INIT ->'
*SELECT CurConsultation
*BROWSE
&&&& curseur mis à jour


* Pour l'appel inter formulaires le code suivant est erroné la variable nvaleur est inconnue
netude = 11111 &&(valeur par exemple)
do form forme2.scx with nvaleur


* il faut
netude = 11111 &&(valeur par exemple)
do form forme2.scx with netude


Cordialement
GLS

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000008931
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3