ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Erreur de cohérence interne menu manager   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

jeu. 14 juin 2012, 21h42
Jean à Grenoble
atoutfox.public.association

Re: Erreur de cohérence interne menu manager

Bonsoir,

une erreur de cohérence interne est une erreur fatale due à un problème grave de
mémoire, de réferences cycliques, .... Je ne pense pas que cela puisse être du à
une 'bête' erreur de syntaxe.

Un des problèmes que je vois est qu'il n'y a pas d'instructions RELEASE POPUP
dans ton exemple; que se passe-t-il si on clique plusieurs fois sur le bouton de
commande ?

Je joins ci-dessous un exemple de popup qui n'a pas tout à fait la même
structure que le tien :
DEFINE POPUP menuregl SHORTCUT FROM MROW()-2,MCOL()+2 ;
  TITLE "listes et historique" FOOTER "factures/règlements" ;
  FONT "Courier New",14 STYLE "B"
STORE 0 TO lnselection
DEFINE BAR 1 OF menuregl PROMPT "\<Liste des repas" ;
  SKIP FOR !m.ThisForm.pt.yacantine ;
  MESSAGE "liste des repas pour tous les enfants de la famille"
DEFINE BAR 2 OF menuregl PROMPT "l\<Iste des études/garderies" ;
  SKIP FOR !ThisForm.pt.yagarderie ;
  MESSAGE "liste des études/garderie pour tous les enfants de la famille"
DEFINE BAR 3 OF menuregl PROMPT "\-" SKIP FOR .T.
DEFINE BAR 4 OF menuregl PROMPT "\<Historique financier (toutes années)" ;
  MESSAGE "liste des factures émises par cette famille pour toutes ses années"
DEFINE BAR 5 OF menuregl PROMPT "i\<Mpayé / trop payé des années précédentes" ;
  MESSAGE "calcul des impayé / trop payé restant des années précédentes"
DEFINE BAR 6 OF menuregl PROMPT "\-" SKIP FOR .T.
DEFINE BAR 7 OF menuregl PROMPT "\<Voir les images des factures (PDF)" ;
  MESSAGE "affiche les PDF de chaque facture de cette famille"
DEFINE BAR 8 OF menuregl PROMPT "\-" SKIP FOR .T.
DEFINE BAR 9 OF menuregl PROMPT "re\<Tour"
ON SELECTION POPUP menuregl lnselection = BAR()
ACTIVATE POPUP menuregl
RELEASE POPUP menuregl     && cette instruction enlève le menu de la mémoire
* ce qui doit permettre de le recréer autant de fois que l'on veut
DO CASE
CASE m.lnselection = 1 && liste des repas
   DO FORM lstrepas WITH m.lcfamille, ""
CASE m.lnselection = 2 && liste des études/garderies
   DO FORM liste_etudes WITH m.lcfamille, ""
CASE m.lnselection = 4 && historique financier
   DO FORM famille_operations_financieres WITH "", "", m.lcfamille
CASE m.lnselection = 5 && impayés / trop payés années précédentes
   DO FORM impayes_toutes_annees_une_famille WITH m.lcfamille, "", ""
CASE m.lnselection = 7 && voir les PDF jme 16/05/2009
   IF ISNULL( ThisForm.pointeur_pdf)
     ThisForm.pointeur_pdf = NEWOBJECT("voir_les_pdf", "routines_factures.prg")
   ENDIF && ISNULL( ThisForm.pointeur_pdf)
   ThisForm.pointeur_pdf.tout( m.lcfamille)
ENDCASE



D'autre part la lettre d'appel n'est pas forcément la première tu peux donc
éviter d'avoir 2 fois F comme lettre d'appel :
DEFINE BAR 4 OF consultation PROMPT "fiche des \<Assurés"
DEFINE BAR 5 OF consultation PROMPT "\<Fiche des Médecins"


Bonne soirée

Jean à Grenoble
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000009199
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3