ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: SQL - Dédoublonner un curseur selon des critères hiérarchisé   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mer. 18 juillet 2012, 15h56

GLS
France France

atoutfox.public.association

Re: SQL - Dédoublonner un curseur selon des critères hiérarchisé

Bonjour,

voila la solution brutale et non élégante que j'ai proposée à Thierry.. elle a l'avantage de faire le bouleau..
a votre optimisation messieurs et mesdames.

SET EXCLUSIVE OFF
CLEAR ALL

SELECT 0
USE bren_.DBF

* Dédoublonner
*!* Pour chaque article différent de cTitre
*!*  - le budget le plus important (bbib_budg)
*!*  - à égalité de budget, le type le plus petit (bbib_type)
*!*  - à égalité de type, les français (France)
*!*  - entre français, le premier dans l'ordre alphabétique (Bbib_Soci)
*!*  - si plusieurs articles pour le même Bbib_Soci, le plus récent (dItem)

* Extraction des différents titre dans un curseur
SELECT DISTINCT(cTitre) AS cTitre FROM bren_ INTO CURSOR TITRE_ NOFILTER
IF RECCOUNT('titre_')>0

  * Création de la structure de la table  finale
  SELECT * FROM bren_ WHERE ID=0 INTO TABLE 'D:\GLS\_THN\BRENFINAL.DBF' READWRITE
  * Zap on ne sait jamais s'il traine un ID=0
  ZAP IN SELECT('BRENFINAL')

  * Pour chaque titre traiter le dédoublonnage
  SELECT TITRE_
  SCAN
    SELECT TITRE_
    * récupération des enregistrements dont le budjet est le plus important
    SELECT *;
      FROM bren_;
      WHERE cTitre=TITRE_.cTitre;
      AND bbib_budg = (SELECT MAX(bbib_budg) FROM bren_ WHERE cTitre=TITRE_.cTitre);
      INTO CURSOR c_tmp READWRITE
    IF RECCOUNT('c_tmp')>0
      * récupération des enregistrements à égalité de budget mais ayant le type le plus petit (bbib_type)
      SELECT *;
        FROM c_tmp;
        WHERE cTitre=TITRE_.cTitre;
        AND bbib_type = (SELECT MIN(bbib_type) FROM c_tmp WHERE cTitre=TITRE_.cTitre);
        INTO CURSOR c_tmp2 READWRITE
      USE IN SELECT('c_tmp')
      IF RECCOUNT('c_tmp2')>0
        * récupération des enregistrements à égalité de budget, de type mais ayant le france le plus grand (france)
        SELECT *;
          FROM c_tmp2;
          WHERE cTitre=TITRE_.cTitre;
          AND france = (SELECT MAX(france) FROM c_tmp2 WHERE cTitre=TITRE_.cTitre);
          INTO CURSOR c_tmp READWRITE
        USE IN SELECT('c_tmp2')
        IF RECCOUNT('c_tmp')>0
          * récupération des enregistrements à égalité de budget, de type, de france mais étant le premier dans l'ordre alphabétique (Bbib_Soci)
          SELECT *;
            FROM c_tmp;
            WHERE cTitre=TITRE_.cTitre;
            AND Bbib_Soci = (SELECT MIN(Bbib_Soci) FROM c_tmp WHERE cTitre=TITRE_.cTitre);
            INTO CURSOR c_tmp2 READWRITE
          USE IN SELECT('c_tmp')
          IF RECCOUNT('c_tmp2')>0
            * récupération des enregistrements à égalité de budget, de type, de france, d'ordre alphabétique (Bbib_Soci) mais ayant la date la plus récente dItem
            SELECT *;
              FROM c_tmp2;
              WHERE cTitre=TITRE_.cTitre;
              AND dItem = (SELECT MAX(dItem) FROM c_tmp2 WHERE cTitre=TITRE_.cTitre);
              INTO CURSOR c_tmp READWRITE
            IF RECCOUNT('c_tmp')>0
              SELECT BRENFINAL
              APPEND FROM DBF('c_tmp')
            ENDIF
            USE IN SELECT('c_tmp')
          ENDIF
        ENDIF
      ENDIF
    ENDIF
  ENDSCAN

  SELECT BRENFINAL
  BROWSE
ENDIF


Cordialement

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000009409
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3