ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: combinaisons des éléments d'un tableau   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mar. 07 août 2012, 10h16
Gregory Adam
Belgique Belgique

atoutfox.public.association

Re: combinaisons des éléments d'un tableau

Bon, je passe par le serveur de news - mais je me suis connecte pour fair un essai
#include FoxPro.h

#define true  .t.
#define false  .f.

*_______________________________________________________________________________

local i, naa

naa =4
local aa[naa]

for i = 1 to naa
  aa[m.i] = transf(m.i)
endfor


local nResult, result[1]

if( WordCombinations(@m.aa, m.naa, @m.result, @m.nResult) )


  for i = 1 to m.nResult
    ?m.result[m.i]
  endfor


endif

*_______________________________________________________________________________
function WordCombinations(aa, naa, result, nResult)

  external array aa, result
  local i

  && asser false
  && (1) calculate nResult
  nResult = 0
  for i = 1 to m.naa
    nResult = m.nResult + Combinations(m.naa, m.i)
  endfor

  dime result[ m.nResult]
  store '' to result

  local resultIndex
  resultIndex = 0


  && (2) Combinaisons avec 1, 2, 3, ... n
  for i = 1 to naa
    if( !WordCombinations_N(@m.aa, m.naa, 1, m.i, @m.result, @m.resultIndex, '') )
      assert false
      exit
    endif
  endfor

  assert m.resultIndex = m.nResult

endfunc
*_______________________________________________________________________________
function WordCombinations_N(aa, naa, startIndex, howMany, result, resultIndex, sList)

  external array aa, result
  local i

  if( m.howMany == 1 )
    for i = m.startIndex to m.naa
      resultIndex = m.resultIndex+ 1
      result[ m.resultIndex] = ltrim(m.sList + ' ' + m.aa[m.i])
    endfor

  else
    for i = m.startIndex to m.naa - m.howMany + 1

      =WordCombinations_N(@m.aa, naa, m.i + 1, m.howMany -1, @m.result, @m.resultIndex, m.sList + ' ' + m.aa[m.i])

    endfor


  endif

endfunc
*_______________________________________________________________________________

function Combinations(n, p)

  do case
  case m.p > m.n
    return 0

  case inlist(m.p, 0, m.n)
    return 1

  case inlist(m.p, 1, m.n-1)
    return m.n

  endcase

  local i, r

  p = min(p, n-p)


  r = n
  for i = 2 to m.p-1 step 2
    r = m.r * (m.n - m.i + 1) * (m.n - m.i) / ( m.i * (m.i+1))
  endfor

  return round(iif(m.i = m.p, m.r * (m.n - m.p + 1) / m.p, m.r),0)

endfunc
*_______________________________________________________________________________



Journal

FoxInCloud (Th. Nivelet) pense que ce message est la bonne réponse ou qu'il est utile
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000009519
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3