mar. 21 août 2012, 08h48
proxifox
France
atoutfox.public.association
Re: RECHERCHE INCREMENTIELLE ET LISTES DEROULANTES
Grâce à ce forum et en réécrivant une partie du code existant, j'ai fini par trouver une réponse à ma question.
Rappel de la problèmatique: Un formulaire de mise à jour des données client, un champ 'Nom' avec d'autres champs associés, dont 3 combo box (Titre du client, nom de la rue, compte analytique). Tous les champs suf le champ 'nom' et le champ 'code client' sont associés à une table 'clients'. Au fur et à mesure qu'on tape des caracttères dans le champ 'nom', le premier client correspondant s'affiche - y compris son nom dans le même champ 'nom'.
Exemple: Je tape 'K' => Il s'affiche 'KABAK'
puis 'KA' => Il s'affiche toujours 'KABAK'
puis 'KAL' => Il s'affiche 'KALAI'
puis 'KALT' => Il s'affiche 'KALTCHEFF'
etc...
Cela fonctionne, les champs du type 'textbox' sont bien rafraichis.... mais pas les combo box!!!
Dans ce formulaire, le champ 'nom' s'appuie sur une classe spécifique 'txt_liste' pour ce type de recherche.
La recherche du client dans la table s'effectue dans l'évenement 'interactivechange'.
Ci dessous, le code d'origine qui ne fonctionne pas correctement, puis le code que j'ai corrigé:
Evenement 'interactivechange' dans une classe 'txt_liste' spécifique
1- Ce qui ne fonctionne pas:
IF EMPTY(THIS.VALUE)
THIS.PARENT.xn_key = 0
THIS.VALUE = ""
ENDIF
SET EXACT OFF
SELECT (THIS.PARENT.source_liste)
IF EMPTY(THIS.PARENT.zone_filtre)
IF SEEK(LEFT(THIS.VALUE,THIS.PARENT.xn_key),THIS.PARENT.source_liste,THIS.PARENT.source_clef)
SELECT (THIS.PARENT.source_liste)
xxvalue=(THIS.PARENT.source_liste)+"."+(THIS.PARENT.colonne_liste)
THIS.VALUE=&xxvalue
THIS.REFRESH
THIS.PARENT.astocker=(THIS.PARENT.clef_liste)
FOR _xn=1 TO THIS.PARENT.xn_key
KEYBOARD '{RIGHTARROW}'
NEXT _nx
ELSE
IF THIS.PARENT.xn_key>0
THIS.VALUE = LEFT(THIS.VALUE,THIS.PARENT.xn_key)
* ajout beg
THIS.PARENT.astocker=THIS.VALUE
FOR _xn=1 TO THIS.PARENT.xn_key
KEYBOARD '{RIGHTARROW}'
NEXT _nx
ENDIF
ENDIF
ELSE
IF SEEK(PADR(gcodeagence,3)+LEFT(THIS.VALUE,THIS.PARENT.xn_key),THIS.PARENT.source_liste,THIS.PARENT.source_clef)
SELECT (THIS.PARENT.source_liste)
xxvalue=(THIS.PARENT.source_liste)+"."+(THIS.PARENT.colonne_liste)
THIS.VALUE=&xxvalue
THIS.REFRESH
THIS.PARENT.astocker=(THIS.PARENT.clef_liste)
FOR _xn=1 TO THIS.PARENT.xn_key
KEYBOARD '{RIGHTARROW}'
NEXT _nx
ELSE
IF THIS.PARENT.xn_key>0
THIS.VALUE = LEFT(THIS.VALUE,THIS.PARENT.xn_key)
* ajout beg
THIS.PARENT.astocker=THIS.VALUE
FOR _xn=1 TO THIS.PARENT.xn_key
KEYBOARD '{RIGHTARROW}'
NEXT _nx
ENDIF
ENDIF
ENDIF
THISFORM.REFRESH()
*
*
2- Ce qui fonctionne:
* ---------------------------------------------------------------------------------------
* Code qui permet de se positionner dans une table à partir des caractères saisis dans
* ce champ
*
* Les propriétés mises en jeu sont:
* 'source_liste' ==> Nom de la table dans laquelle on cherche des valeurs
* 'source_clef' ==> Nom de l'index utilisé
* 'colonne_liste' ==> Nom du champ dans la table (dans le formulaire, le champ
* n'est pas lié à une colonne particulière de la base)
* 'Zone_filtre' ==> Si cette propriété est renseignée, on filtre sur le code agence
* 'xn_key' ==> Nombre de caractères saisis
* 'astocker' ==> Ne sert à rien dans le formulaire 'frmdprop'
* -----------------------------------------------------------------------------
IF EMPTY(THIS.VALUE)
THIS.PARENT.xn_key = 0
THIS.VALUE = ""
ENDIF
SET EXACT OFF && On doit comparer les valeurs sur des clés partielles
SELECT (THIS.PARENT.source_liste)
IF EMPTY(THIS.PARENT.zone_filtre)
IF SEEK(LEFT(THIS.VALUE,THIS.PARENT.xn_key),THIS.PARENT.source_liste,THIS.PARENT.source_clef)
SELECT (THIS.PARENT.source_liste)
xxvalue=(THIS.PARENT.source_liste)+"."+(THIS.PARENT.colonne_liste)
THIS.VALUE=&xxvalue
THIS.PARENT.astocker=(THIS.PARENT.clef_liste)
ELSE
IF THIS.PARENT.xn_key>0
THIS.VALUE = LEFT(THIS.VALUE,THIS.PARENT.xn_key) && Seuls vont apparaitre les caractères saisis dans le champ
* ajout beg
THIS.PARENT.astocker=THIS.VALUE
ENDIF
ENDIF
ELSE && Idem en utilisant le code agence
IF SEEK(PADR(gcodeagence,3)+LEFT(THIS.VALUE,THIS.PARENT.xn_key),THIS.PARENT.source_liste,THIS.PARENT.source_clef)
SELECT (THIS.PARENT.source_liste)
xxvalue=(THIS.PARENT.source_liste)+"."+(THIS.PARENT.colonne_liste)
THIS.VALUE=&xxvalue
THIS.PARENT.astocker=(THIS.PARENT.clef_liste)
ELSE
IF THIS.PARENT.xn_key>0
THIS.VALUE = LEFT(THIS.VALUE,THIS.PARENT.xn_key)
* ajout beg
THIS.PARENT.astocker=THIS.VALUE
ENDIF
ENDIF
ENDIF
*!* THISFORM.REFRESH()
_SCREEN.ACTIVEFORM.REFRESH && Utilisable à partir d'une barre de menus
THIS.SELSTART = THIS.PARENT.xn_key && Positionne le curseur après le dernier caractère saisi
Quelle différence? L'instruction pour positionner le curseur dans le champ nom doit se trouver APRES le 'refresh()' du formulaire.
L'instruction 'THISFORM.REFRESH()' dans le cas traité est équivalente à '_SCREEN.ACTIVEFORM.REFRESH' - on peut laisser indifféremment l'une ou l'autre
Les lignes:
FOR i=1 TO THIS.PARENT.xn_key
KEYBOARD '{RIGHTARROW}'
NEXT i
sont équivalentes à "THIS.SELSTART = THIS.PARENT.xn_key" - on peut laisser indiféremment les unes ou l'autre, seule la PLACE de cette instruction est déterminante.
Voilà, sauf remarques complémentaires, je pense que le sujet est clos.
Merci pour votre aide - P ROUGERIE
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000009625