ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: utilisation d'un timer sous vfp8   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

dim. 16 décembre 2012, 10h18

Francis Faure
France France

atoutfox.public.association

Re: utilisation d'un timer sous vfp8

Bonjour Christian,

interval à 4000 veut dire un déclenchement toute les 4 secondes
enabled à .T. veut dire que le timer est activé et appel sa methode timer()

Attention : le timer est actif dés lors qu'il y a une attente et donc gestion des événements
classiquement lorsque la commande :
READ EVENTS
est lancé dans ton programme : en attente d'une form ou simplement d'un menu global ayant "une sortie" avec "CLEAR EVENTS"
L'autre solution est d'incorporer le timer dans un formulaire modal

si c'est bien le cas dans ton programme et que tu log bien les appels au timer,
il faudrait voir le nom du fichier testé (caractère spéciaux etc...),
et s'il n'est pas dans un répertoire protégé de windows, ou sur un réseau : voir les droits

ci après un programme de test fonctionnel

Cordialement
Francis


* Créer un objet timer
loObjectTimer = Createobject("myTimer")
loObjectTimer.File = "c:\temp\test.txt"
loObjectTimer.Enabled=.T.

* Créer une form d'attente
loForm=Createobject("MyForm")
loForm.visible=.T.

READ EVENTS && attente fermture de la form et execution du Timer

loForm=Null
loObjectTimer=Null


Define Class MyTimer As Timer
  Interval = 1*1000 && nombre de milliseconde entre chaque déclenchement
  Enabled =.F. && pas démarré par défaut
  File = "" && fichier a tester
  Nombre = 0 && nombre d'appel (juste pour affichage)

  Procedure Timer()
    this.nombre=this.nombre+1
    Local lcString As String
    lcString = Ttoc(Datetime())+ " "
    lcString = lcString + "("+ALLTRIM(STR(this.nombre,10,0))+ ") "
    If Not Empty(This.File)
      lcString = lcString + "Le fichier "+This.File+ " : "
      lcString = lcString + Iif(File(This.File), "existe", "n'existe pas")
    Endif
    Set Message To m.lcString && affiche en barre de message
    ? m.lcString && affiche dans la fenetre encours (normalement la form d'attente)
  Endproc
Enddefine


Define Class MyForm As Form
  Top = 10
  Left = 10
  Height = _screen.Height-50
  Width = _screen.width-50
  Caption = "Test : Fermez cette fenetre pour arrêter le test."
  Closable = .T.
  Name = "MyForm1"
  backcolor=RGB(255,255,255)

  PROCEDURE destroy()
    DODEFAULT()
    CLEAR events
  endproc

Enddefine


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000010374
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3