ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Controle OLEBOUNDCONTROL   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mer. 02 janvier 2013, 22h00

GLS
France France

atoutfox.public.association

Re: Controle OLEBOUNDCONTROL

Bonjour

je n'utilise plus les champs de type G (général) pour stocker des images, mais des champs blob avec un filetostr() pour remplir le champ blob avec le contenu d'un fichier bitmap et strtofile() pour recréer le fichier bitmap sur disque avant son utilisation.

Dans les scx c'est l'OLE image qui est utilisé pour l'affichage et sa propriété PICTURE qui est utilisée pour la référence avec le fichier bitmap.
Dans les impressions, je crée un cursor avec un champ W (blob), ou j'ai dans la table liée à l'impression un champ w, dans lequel je stocke filetostr().
Dans le report j'ajout un control OLE pour chaque image avec comme type de source de controle: "une expression ou nom de variable" (ex: eImage comme nom de variable)
J'ai une classe dans un VCX dérivée de REPORTLISTENER:
- Dans l'init() de cette classe ReportListener j'ai le code suivant:
This.ObjetImg   = NULL
This.ImgPictureVal  = ''
This.LISTENERTYPE   = 0 && 1 = Preview Listener | 0 = default output

- Dans cette classe ReportListener j'ai ajouté la méthode InitObjetImg() contenant le code suivant:
LPARAMETERS p_Field_graph
* Ajout d'un objet ObjetImage basé sur la classe de base IMAGE
* pour permettre le lien entre le REPORT et la classe ReportListener
* afin d'imprimer les images contenues dans le champ BLOB (p_field)
THIS.ImgPictureVal = p_Field_graph
THIS.objetImg = NEWOBJECT('glsimg')
THIS.objetImg.PICTUREVAL  = p_Field_graph

- Dans la méthode BeforBand() de cette classe ReportListener j'ai le code suivant:
LPARAMETERS nBandObjCode, nFRXRecno
*-- Before the DETAIL band is rendered, ;
*-- just redraw the IMAGE object so that it has
*-- the correct picture from the BLOB field.
IF nBandObjCode = 4 && si c'est un Page Header
  IF !EMPTY(THIS.ImgPictureVal)
    THIS.ObjetImg.PICTUREVAL = EVALUATE(THIS.ImgPictureVal)
  ENDIF
ENDIF
[/VP]

Dans le code de l'impression j'ai:
[VFP]
m.loRL = NEWOBJECT("MonReportlistener","maclasse.vcx")
* Initialisation de la variable eImage utilisée dans le report pour afficher l'image
m.loRL.InitObjetImg('c_curseur.image') && champ blob contenant le fichier bitmap
SELECT c_curseur
* Impression a l'aide de la procédure ImprimeReportListener
=ImprimeReportListener('monreport.frx','REPORT','ALL', m.loRL, 'TO PRINTER')


PROCEDURE ImprimeReportListener
  LPARAMETERS p_etat, p_type, p_etendu, p_objet, p_mode
  LOCAL cExt AS CHARACTER , oPc AS OBJECT , oRl AS OBJECT
  * Extension Handler
  SET DATE French
  m.oRl=p_objet
  m.cExt = NEWOBJECT("MaPrevisualisation")
  * Preview container
  m.oPc = .NULL.
  DO (_REPORTPREVIEW) WITH m.oPc
  m.oPc.CAPTION = "Titre de l'apercu"
  m.oPc.ZoomLevel = 3 && 50%
  m.oPc.ToolbarIsVisible=.T.
  m.oPc.CanvasCount = 2 && nombre de page dans l'aperçu
  m.oPc.SetExtensionHandler(m.cExt) && liaison avec l'ExtensionHandler 'MaPrevisualisation'
  IF p_mode="PREVIEW"
    m.oRl.LISTENERTYPE = 1  && Aperçu écran
  ELSE
    m.oRl.LISTENERTYPE = 0  && Impression
  ENDIF
  m.oRl.PREVIEWCONTAINER = m.oPc
  IF p_type='LABEL'
    LABEL FORM &p_etat OBJECT m.oRl &p_etendu
  ELSE
    REPORT FORM &p_etat OBJECT m.oRl &p_etendu && NOPAGEEJECT
  ENDIF
  m.cExt = .NULL.
  RELEASE cExt, oPc, oRl
ENDPROC

DEFINE CLASS MaPrevisualisation AS CUSTOM
  PROCEDURE SHOW( iStyle )
    THIS.PreviewForm.TOOLBAR.DOCK(0) && Doctker la barre d'outils en haut
    THIS.PreviewForm.WINDOWSTATE =2  && Maximiser la fenétre
  ENDPROC
ENDDEFINE


C'est un peu complexe à comprendre, mais une fois mis en place cela permet d'imprimer des bitmaps (BMP;JPG,PNG etc..) correctement dans des reports ou labels..
Il y a des posts sur AtoutFox plus élaboré sur ce sujet..

Cordialement
GLS

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000010536
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3