ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: en tant qu'administrateur ...   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

lun. 28 janvier 2013, 15h36

Francis Faure
France France

atoutfox.public.association

Re: en tant qu'administrateur ...

Pour être complet sur ce sujet : il y a une contribution de Mike incontournable :
http://www.atoutfox.org/articles.asp?ACTION=FCONSULTER&ID=0000000766
Cordialement
Francis


Le lun. 28 janvier 2013, 15h33 Francis Faure a écrit :
> Pour extraire le manifest de l'exe, ci joint un source et forcer en tant qu'adminsitrateur
>
> dans le fichier manifest xm généré : modifier requestedExecutionLevel avec requireAdministrator (au lieu de asInvoker )
> <requestedExecutionLevel level="requireAdministrator" />
>
> et rebuilder... tu auras la demande d'élévation si tu le lance (et une icône bouclier).
>
> Cordialement
> Francis
>
> PS : bien sur il faut VFP9 S2 minimum
>
>
>
Declare Long LoadLibrary In WIN32API String
Declare Long FindResource In WIN32API Long, Long, Long
Declare Long LoadResource In WIN32API Long, Long
Declare Long SizeofResource In WIN32API Long, Long
Declare Long FreeLibrary In WIN32API Long
Declare Long FreeResource In WIN32API Long
=ExtraireManifest("unite:\dir\tonprojet.exe")
* ...

Procedure ExtraireManifest(lsFile As String)
Local hModule
If File(m.lsFile+".manifest")
=Messagebox("Le Fichier Manifest existe déjà. Extraction annulée.")
Return
Endif
If File(m.lsFile)
m.hModule = LoadLibrary(m.lsFile)
m.lnRsrc = FindResource(m.hModule, 1, 24)
m.lnMem = LoadResource(m.hModule, m.lnRsrc)
m.lnSize = SizeofResource(m.hModule, m.lnRsrc)
m.lcManifest = Sys(2600, m.lnMem, m.lnSize)
FreeResource(m.lnMem)
FreeLibrary(m.hModule)
Set Safety Off
=Strtofile(m.lcManifest, m.lsFile+".manifest", 0)
Set Safety On
Else
=Messagebox("Le fichier" + m.lsFile + " n'existe pas",16)
Endif
Endproc

>
>
>
>
>
> Le lun. 28 janvier 2013, 15h24 Francis Faure a écrit :
> > En compléments :
> >
> > - Si tu veux qu'un projet VFP se lance toujours "en tant qu'administrateur" : il te suffit d'extraire le manifest et de le modifier
> > - Si tu veux lancer un autre programme en tant qu'administrateur (ou lui même avant un QUIT) après un test IsUserAnAdmin()
Function RunAsAdministrator(lsApplication As String, lsDir As String)
Declare Integer ShellExecute In shell32.Dll ;
Integer hndWin, ;
STRING cAction, ;
STRING cFileName, ;
STRING cParams, ;
STRING cDir, ;
INTEGER nShowWin
=ShellExecute(0,"RunAs",m.lsApplication,"",m.lsDir,1)
Endfunc

> >
> >
> >
> > Le lun. 28 janvier 2013, 15h21 Francis Faure a écrit :
> > > Bonjour Thierry
> > >
> > > Pour savoir si un programme est lancé "en tant qu'administrateur" :
> > >
*

* IsAdmin() retourne True si programme lancé en admin

*

Function IsAdmin() As Boolean
Local liResult As Integer
Try
Declare Integer IsUserAnAdmin In Shell32
liResult = IsUserAnAdmin()
Catch
*** Compatibilité VIELLE Version de Windows

liResult = 1
Endtry
If m.liResult = 0
Return .F.
Endif
Return .T.
Endfunc

> > >
> > > De mémoire : Il me semble que ce source est issue d'une contribution de Mike
> > >
> > > Cordialement
> > > Francis
> > >
> > > Le lun. 28 janvier 2013, 13h21 FoxInCloud a écrit :
> > > > Bonjour,
> > > >
> > > > Connaissez vous le moyen de savoir si un programme VFP tourne "en tant qu'administrateur" ?
> > > >
> > > > A défaut, connaissez-vous un programme d'installation capable de créer un raccourci qui s'exécute "en tant qu'administrateur" ?
> > > > (e.g. un raccourci vers VFP9.exe)
> > > >
> > > > Merci,
> > > > thn
> > > >
> > > >
> > > > .
> > > >
> > >
> > >
> > >
> > > .
> > >
> >
> >
> >
> > .
> >
>
>
>
> .
>


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000010897
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3