ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: grid conditional formating   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mar. 19 mars 2013, 15h27
Gregory Adam
Belgique Belgique

atoutfox.public.association

Re: grid conditional formating

J;ai cree une classe cnt: container avec des shapes : shape1, shape2, shape3, .... shape6

Dans l'init du grid, je cherche la colonne monchamp1
- je remplace le currentcontrol par la classe cnt
- je mets le DynamicBackColor de la colonne. Ceci est une methode du form: SetColors()

&& grid init
if( !dodefault() )
  return .f.
endif

with m.this
  local i, cs
  for i = .ColumnCount to 1 step -1

    with .Columns[m.i]
      cs = lower(justext(.ControlSource))

      do case
      case m.cs == 'monchamp1'
        =.RemoveObject(.CurrentControl)
        =.AddObject('Cnt1', 'cnt')
        .cnt1.Visible = .t.
        .Sparse = .f.

        .DynamicBackColor = [m.thisform.SetColors(m.this, "] + .Name + [", 'cnt1', ] + .ControlSource + [)]
      endcase
    endwith
  endfor
endwith


La methode SetColors
lparameters gridObj, colName, controlName, fld

with getpem(getpem(m.gridObj, m.colname), m.controlName)

  local i, colour, c, shapeName
  for i = 1 to len(m.fld)

    c = substr(m.fld, m.i, 1)
    colour = icase ( m.c == '0', RGB(255,0,0), ;
             m.c == '1', RGB(0,168,2), ;
             m.c == '2', RGB(255,255,0), ;
             m.c == '3', RGB(192,192,192), ;
             rgb(255,255,128))


    shapeName= 'Shape' + padl(m.i, 1)

    .&shapeName..BackColor = m.colour

  endfor

  return rgb(255,255,255)

endwith



Journal

RHJ pense que ce message est la bonne réponse ou qu'il est utile
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000011604
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3