lun. 01 avril 2013, 12h54
Gregory Adam
Belgique
atoutfox.public.association
Re: Problème avec This.Parent
Michel,
>.... les objets contenus sont toujours créés avant leur conteneur! Au moment de l'Init, le parent n'est pas défini.
C'est vrai, mais le parent est bel et bien defini - pour autant qu'on utilise la bonne methode pour l'ajouter
this.AddObject() ou this.NewObject()
>alors modifie ton Init pour recevoir un paramètre, passe cet parent
>en paramètre dans l'init, teste dans l'init la qualité du paramètre reçu (Vartype et PemStatus), et tout
>ira bien.
Je deconseille
Je me demande si tout ira bien - il y a un piege - foxpro n'a pas de Garbage Collection comme en .Net
Regarde ce bout de code et tu vois qu'aucun de ces deux objects ne sera detruit
*________________________________________________________________________________
function do_it()
&&= do_it_28150()
local obj
obj = createobject('ClassA')
obj = null
endfunc
*________________________________________________________________________________
define class ClassA as Custom
Tickets = null
protected function init()
=dodefault()
this.Tickets = createobject('ClassB', m.this)
endfunc
protected function Destroy()
activate screen
?'Destroy ', this.Name
return dodefault()
endfunc
enddefine
*________________________________________________________________________________
define class ClassB as Custom
Ptr = null
protected function init(ptr)
=dodefault()
this.Ptr = m.ptr
endfunc
protected function Destroy()
activate screen
?'Destroy ', this.Name
return dodefault()
endfunc
enddefine
*________________________________________________________________________________
Il faut un traitement specialise pour la destruction
J'ajoute une methode Release() a ClassA. Une fois executee, toutes les references a seront replacees par null, notamment la propriete Ptr de classeB
Mais cette pratique, je deconseille aussi - il est facile d'oublier d'appeler le Release()
*________________________________________________________________________________
function do_it()
&&= do_it_28150()
local obj
obj = createobject('ClassA')
=m.obj.Release()
endfunc
*________________________________________________________________________________
define class ClassA as Custom
Tickets = null
protected function init()
=dodefault()
this.Tickets = createobject('ClassB', m.this)
endfunc
protected function Destroy()
activate screen
?'Destroy ', this.Name
return dodefault()
endfunc
function Release()
release this
enddefine
*________________________________________________________________________________
define class ClassB as Custom
Ptr = null
protected function init(ptr)
=dodefault()
this.Ptr = m.ptr
endfunc
protected function Destroy()
activate screen
?'Destroy ', this.Name
return dodefault()
endfunc
enddefine
*________________________________________________________________________________
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000011675