ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Grid : saisie 'en descendant'   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

ven. 14 juin 2013, 14h54
Gregory Adam
Belgique Belgique

atoutfox.public.association

Re: Grid : saisie 'en descendant'

Gilles,

Partout
#define true .t.
#define false .f.


(1) Dans ma classe form je mets une method
&& GetActiveControl
lparameters acObj, colObj, gridObj

store null to acObj, colObj, gridObj

if( type('m.thisform.ActiveControl') == T_UNDEFINED )
  return false
else
  acObj = m.thisform.ActiveControl
endif

if( proper(m.acObj.BaseClass) == 'Grid' )

  gridObj = m.acObj

  local activeCol, i
  activeCol = m.acObj.ActiveColumn

  if( !empty(m.activeCol) )

    for i = 1 to m.gridObj.ColumnCount
      colObj = m.gridObj.Columns[m.i]
      if( m.colObj.ColumnOrder = m.activeCol)
        exit
      endif
    endfor

    for i = 1 to m.colObj.ControlCount
      if( m.colObj.Controls[m.i].Name == m.colObj.CurrentControl )
        acObj = m.colObj.Controls[m.i]
        exit
      endif
    endfor
  endif
endif


(2) Dans ma classe grid - j'ajouite une method qui me dit si c'est la derniere colonne qui est enabled
IsLastEnabledColumn()
lparameters obj

if( !(vartype(m.obj) == T_OBJECT) )
  return false
endif

if( !( m.obj.BaseClass == 'Column') )
  return false
endif


local i, maxColObj, maxColOrder, colObj

maxColObj = null
maxColOrder = -1


for i = 1 to m.obj.Parent.ColumnCount
  colObj = m.obj.Parent.Columns[m.i]

  do case
  case !m.colObj.Visible
    loop

  case !m.colObj.Enabled
    loop

  case m.colObj.ColumnOrder < m.maxColOrder
    loop

  otherwise
    maxColObj = m.colObj
    maxColOrder = m.colObj.ColumnOrder

  endcase
endfor


do case
case !isnull(m.maxColObj)
  return m.maxColObj == m.obj

&& only one column here
case m.obj.ReadOnly
  return false

case !m.obj.Enabled
  return false

case !m.obj.Visible
  return false

otherwise
  return true

endcase


(3) Le form

Load
=dodefault()

create cursor gilles ;
(  g1  c(10), ;
  g2  c(10), ;
  g3  c(10), ;
  g4  c(10) ;
)

for i = 1 to 20
  insert into gilles values(transform(m.i), transform(m.i), transform(m.i), transform(m.i))
endfor

go top


Le grid y est avec RecordSource = 'Gilles'

Form.keyPress
[vfp
LPARAMETERS nKeyCode, nShiftAltCtrl

local acObj, colObj, gridObj
do case
case !empty(m.nShiftAltCtrl)

case m.nKeyCode <> 0x0d

case !m.thisform.GetActiveControl(@m.acObj, @m.colObj, @m.gridObj)

case isnull(m.gridObj)

case !( lower(m.gridObj.RecordSource) == 'gilles')

case !m.gridObj.IsLastEnabledColumn(m.colObj)

otherwise
DoEvents
KeyBoard '{DNARROW}'


endcase
[/vfp]

Tu peux changer la sequence des colonnes (avec la souris) - ce sera toujours ENTER dans la derniere qui est visible qui ira a la ligne suivante


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000012134
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3