ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: EXCEL VFP9   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

ven. 12 juillet 2013, 15h14
PHILIPPE
atoutfox.public.association

Re: EXCEL VFP9

J'avais penser à faire une sélection pour les modifier en même temps mais le
problème se trouve pour les bordures, si je prends une ligne complète les
bordures ne se font qu'autour de la ligne et pas à l'intérieur.

"Gregory Adam" a écrit dans le message de groupe de discussion :
krotoc$2ubv$1@news.niouzes.net...

Philippe,

J'ai fait un petit programme qui remplit 500 lignes, 20 colonnes par ligne
Par cellule je mets la valeur et numberFormat

(1) Normal 14.37 sec

(2)
Je fais un with cellule, value = , numberformat = , endwith : 11.58 sec

Ce n'est pas la gloire


(3) L'astuce est de diminuer les aller-retour et traiter une ligne a la fois
( donc pas cellule par cellule)
Je passé a 1.04 sec


Il y a aussi la possibilite de traiter plusieurs lignes a la fois - je le
laisse pour toi

Exemples des 3 programmes
*________________________________________________________________________________
function Do_it()

#define NUMBER_ROWS 500
#define NUMBER_COLS 20


&& =xl_Test_1() && 14.37
&& =xl_Test_2() &&11.58
=xl_Test_3() && 1.04
endfunc
*________________________________________________________________________________
function xl_Test_1()

local xlObj, xlDisposableObj, sheetObj, i, j


xlObj= createobject('Excel.Application')

assert Disposable_Excel_Object(@m.xlDisposableObj, xlObj)
xlObj.DisplayAlerts = false

=xlObj.workBooks.Add()

sheetObj = m.xlObj.workBooks(1).Sheets(1)

=TimeStart('Fill')

for i = 1 to NUMBER_ROWS
for j =1 to NUMBER_COLS
sheetObj.Cells(m.i, m.j).Value = m.i + m.j/100
sheetObj.Cells(m.i, m.j).NumberFormat = '######.##'
endfor

endfor
=TimeEnd()
&& =m.xlObj.WorkBooks(1).SaveAs('d:\tmp\1.xlsx')

endfunc
*________________________________________________________________________________
function xl_Test_2()

local xlObj, xlDisposableObj, sheetObj, i, j


xlObj= createobject('Excel.Application')

assert Disposable_Excel_Object(@m.xlDisposableObj, xlObj)
xlObj.DisplayAlerts = false

=xlObj.workBooks.Add()

sheetObj = m.xlObj.workBooks(1).Sheets(1)

=TimeStart('Fill')

for i = 1 to NUMBER_ROWS
for j =1 to NUMBER_COLS
with sheetObj.Cells(m.i, m.j)
..Value = m.i + m.j/100
..NumberFormat = '######.##'
endwith
endfor

endfor
=TimeEnd()
&& =m.xlObj.WorkBooks(1).SaveAs('d:\tmp\1.xlsx')

endfunc
*________________________________________________________________________________
function xl_Test_3()

local xlObj, xlDisposableObj, sheetObj, i, j


xlObj= createobject('Excel.Application')

assert Disposable_Excel_Object(@m.xlDisposableObj, xlObj)
xlObj.DisplayAlerts = false

=xlObj.workBooks.Add()

sheetObj = m.xlObj.workBooks(1).Sheets(1)

local aa[NUMBER_COLS]
=TimeStart('Fill')

for i = 1 to NUMBER_ROWS
for j =1 to NUMBER_COLS
aa[m.j] =  m.i + m.j/100
endfor

with m.sheetObj.Range(m.sheetObj.Cells(m.i, 1), m.sheetObj.Cells(m.i,
NUMBER_COLS))
..Value = ArrayPasser(@m.aa)
..NumberFormat = '######.##'
endwith
endfor
=TimeEnd()
&& =m.xlObj.WorkBooks(1).SaveAs('d:\tmp\1.xlsx')

endfunc
*________________________________________________________________________________
function ArrayPasser(aa)

return @m.aa
endfunc
*________________________________________________________________________________


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000012518
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3