ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Question de CTOBIN...   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mar. 16 juillet 2013, 17h15
Gregory Adam
Belgique Belgique

atoutfox.public.association

Re: Question de CTOBIN...

Francis,

As-tu deja fini par trouver ?

Le code ci-dessous donne bien -1.2. J'ai aussi teste quelques exemples du lien http://en.wikipedia.org/wiki/Double_precision


&& DoubleClass
*_______________________________________________________________________________
#include  "FoxPro.h"

#define true  .t.
#define false  .f.
*_______________________________________________________________________________

local obj, s, v
obj = createobject('DoubleClass')
s = CHR(51)+CHR(51)+CHR(51)+CHR(51)+CHR(51)+CHR(51)+CHR(243)+CHR(191)

assert m.obj.GetDoubleValue(@m.v, m.s, true)

?v

assert m.obj.GetDoubleValue(@m.v, replicate(chr(0), 8), true)

?v
assert m.obj.GetDoubleValue(@m.v, strconv(strtran('3ff0 0000 0000 0000', ' '),16), false)
?v

assert m.obj.GetDoubleValue(@m.v, strconv(strtran('4000 0000 0000 0000', ' '),16), false)
?v


assert m.obj.GetDoubleValue(@m.v, strconv(strtran('0000 0000 0000 0001', ' '),16), false)
?v

assert m.obj.GetDoubleValue(@m.v, strconv(strtran('000f ffff ffff ffff', ' '),16), false)
?v

assert m.obj.GetDoubleValue(@m.v, strconv(strtran('0010 0000 0000 0000', ' '),16), false)
?v

assert m.obj.GetDoubleValue(@m.v, strconv(strtran('7fef ffff ffff ffff', ' '),16), false)
?v

*===============================================================================
*===============================================================================
*===============================================================================
define class DoubleClass as Cursor

  protected DoubleString
  protected Sign
  protected Exponent
  protected Fraction

*_______________________________________________________________________________
function GetDoubleValue(v as Double, s as String, isLittleEndian as Boolean)

  local success
  success = true


  do case
  case !m.success

  case !m.this.SetDoubleString(m.s, m.isLittleEndian )
    assert false
    success = false

  case !m.this.SetSign()
    assert false
    success = false

  case !m.this.SetExponent()
    assert false
    success = false

  case !m.this.SetFraction()
    assert false
    success = false

  && exceptions
  case m.this.IsZeroExponent()

    do case
    case m.this.IsZeroFraction()
      v = 0.00

    && subnormals
    case !m.this.GetSubNormalValue(@m.v)
      assert false
      success = false

    endcase

  case m.this.IsHighExponent()
    do case
    case m.this.IsZeroFraction()
      do case
      case m.this.Sign < 0
        error 'Negative infinity'
      otherwise
        error 'Positive infinity'

      endcase

      success = false
    otherwise
      error 'NaN'
      success = false

    endcase
  otherwise
    v = m.this.Sign * m.this.Fraction * 2^(m.this.Exponent)


  endcase

  return m.success
endfunc
*_______________________________________________________________________________
protected function GetSubNormalValue(v)
  v = m.this.Sign * (m.this.Fraction-1.0) * 2^(m.this.Exponent+1)

endfunc

#if false
  store as a Little Endian string
#endif
protected function SetDoubleString(s, isLittleEndian )

  local success
  success = true

  do case
  case !m.success

  case m.isLittleEndian
    this.DoubleString =  cast(m.s as varbinary(8))

  otherwise
    local i
    this.DoubleString = ''
    for i = 8 to 1 step -1
      this.DoubleString = m.this.DoubleString + substr(m.s, m.i, 1)

    endfor
    this.DoubleString =  cast( m.this.DoubleString as varbinary(8))

  endcase

  return m.success
endfunc
*_______________________________________________________________________________
protected function SetSign()

  this.Sign = iif(bittest(m.this.DoubleString, 63), -1, 1)

endfunc
*_______________________________________________________________________________
#if false
  -1023  means it was 0x000  ( zero and subnormals)
  1024  means it was 0x7ff  ( infinity and NaN)
#endif
protected function SetExponent()


  local i, s, x

  s = m.this.DoubleString
  x = 0


  for i = 62 to 52 step -1
    x = bitor (;
          bitlshift(m.x, 1), ;
          iif(bittest(m.s, m.i), 1, 0) ;
          )
  endfor
  this.Exponent = m.x - 1023

endfunc
*_______________________________________________________________________________
#if false
    1.00 means zero mantissa
#endif
protected function SetFraction()

  local i, s, f

  s = m.this.DoubleString
  f = 0.0

  for i = 0 to 51
    f = (m.f + iif(bittest(m.s, m.i), 1.00, 0)) / 2.0
  endfor

  this.Fraction =  m.f + 1.00

endfunc
*_______________________________________________________________________________
function IsZeroExponent()

  return m.this.Exponent == -1023
endfunc
*_______________________________________________________________________________
function IsHighExponent()

  return m.this.Exponent == 1024
endfunc
*_______________________________________________________________________________
function IsZeroFraction()

  return m.this.Fraction == 1.00
endfunc
*_______________________________________________________________________________
enddefine
*===============================================================================
*===============================================================================
*===============================================================================


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000012544
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3