ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Utiliser la date et heures du serveur sur un poste client   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mar. 23 juillet 2013, 11h15
Gregory Adam
Belgique Belgique

atoutfox.public.association

Re: Utiliser la date et heures du serveur sur un poste client

Bonjour,

Pour obtenir la date et l'heure d'une machine dans le reseau

( ne pas utilizer //localhost pour le pc local)

#include  "FoxPro.h"

#define true  .t.
#define  false  .f.

*_______________________________________________________________________________
function do_it()


  local dtGMT, dtLocal

  && local
  ?GetServerDateTime(null, @m.dtGMT, @m.dtLocal), dtGMT, dtLocal

  && autre pc/serveur
  ?GetServerDateTime('\\Server', @m.dtGMT, @m.dtLocal), dtGMT, dtLocal

endfunc
*_______________________________________________________________________________
function GetServerDateTime(servername, dtGMT, dtLocal)

  local success
  success = true

  local svr, ptr
  ptr = 0

  if( !isnull(m.servername) )
    svr =  strconv(m.servername + chr(0), 5)
  else
    svr = null
  endif

  do case
  case !m.success

  case !empty(Core_Api_NetRemoteTOD(@m.svr, @m.ptr))
    assert false
    success = false

  otherwise
    && copy
    s = sys(2600, m.ptr, 48)
    if( !empty(Core_Api_NetApiBufferFree(m.ptr)) )
      assert false
      success = false
    endif

  endcase

  do case
  case !m.success

  otherwise
    && http://msdn.microsoft.com/en-us/library/windows/desktop/aa370959(v=vs.85).aspx
    local dd, mm, yy, hours, mins, secs, tz
    dd = ctobin(substr(m.s, 33, 4), '4rs')
    mm = ctobin(substr(m.s, 37, 4), '4rs')
    yy = ctobin(substr(m.s, 41, 4), '4rs')
    hours = ctobin(substr(m.s, 9, 4), '4rs')
    mins = ctobin(substr(m.s, 13, 4), '4rs')
    secs = ctobin(substr(m.s, 17, 4), '4rs') + ctobin(substr(m.s, 21, 4), '4rs')/100
    tz = ctobin(substr(m.s, 25, 4), '4rs')

    dtGMT = datetime(m.yy, m.mm, m.dd, m.hours, m.mins, m.secs)
    dtLocal =m.dtGMT - m.tz * 60
  endcase
  return m.success

endfunc
*_______________________________________________________________________________
&& http://msdn.microsoft.com/en-us/library/windows/desktop/aa370612(v=vs.85).aspx
function Core_Api_NetRemoteTOD(uncServerName, bufferPtr)

  declare long NetRemoteTOD in NetApi32.dll as Core_Api_NetRemoteTOD ;
    string @uncServerName, long@ bufferPtr

  return Core_Api_NetRemoteTOD (@m.uncServerName, @m.bufferPtr)

endfunc
*_______________________________________________________________________________
&& http://msdn.microsoft.com/en-us/library/windows/desktop/aa370304(v=vs.85).aspx
function Core_Api_NetApiBufferFree(bufferPtr)

  declare long NetApiBufferFree in NetApi32.dll as Core_Api_NetApiBufferFree ;
    long bufferPtr

  return Core_Api_NetApiBufferFree(m.bufferPtr)

endfunc
*_______________________________________________________________________________


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000012618
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3