ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Utiliser la date et heures du serveur sur un poste client   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mar. 23 juillet 2013, 21h42

Luc
France France

atoutfox.public.association

Re: Utiliser la date et heures du serveur sur un poste client

Une solution par la création d'une table sur un répertoire connu de la machine distante (ca suppose qu'on a les droits d'écriture dessus). A améliorer car l'optimisation fait qu'on cherchera toujours sur la même machine à partir de la 2ème fois

MessageBox(MachineDateTime("\\portable-dell2\Pucette3"))

***************************************************************************************************************************************
* Renvoie la date et l'heure de la machine dont on fournit le chemin
Function MachineDateTime
  Lpara pcPath, pbForceLectureRéseau


  If Type("giDécalageAvecLeServeur") = "U"
    * Le décalage de temps avec le serveur principal n'a pas été déterminé
    * Le déterminer maintenant

    Local lsFich, lsTime, lvSeleAvant, lvTimeFichier, lvTimeMachine ;
      , lvPucetteDateTime, lsOldSetSeconds, lsOldSetSafe

    m.pcPath = Addbs(m.pcPath)

    * Créer un nouveau fichier sur la machine distante
    m.lvSeleAvant = Sele()

    * Une erreur est arrivée à Elliant : accès au fichier refusé
    m.lsFich = m.pcPath+"Heure"+Alltr(Str(Rand()*1000))+".dbf"
    Do While File(m.lsFich)
      m.lsFich = m.pcPath + "Heure"+Alltr(Str(Rand()*1000))+".dbf"
    Enddo
    Create Table (lsFich) Free (Heure N(1,0))
    m.lvTimeMachine = Datetime()
    m.lsOldSetSeconds = Set("Seconds")
    Set Seconds ON
    m.lsTime = Dtoc(fdate(m.lsFich)) + " " + ftime(m.lsFich)
    Set Seconds &lsOldSetSeconds
    Use
    Sele (lvSeleAvant)

    Erase (m.lsFich)

    m.lvTimeFichier = CTOT(m.lsTime)
    Public giDécalageAvecLeServeur
    m.giDécalageAvecLeServeur = m.lvTimeFichier - m.lvTimeMachine

  Endif

  * Le décalage de temps avec le serveur principal a déja été déterminé
  * L'utiliser pour déterminer l'heure sur le serveur principal
  m.lvPucetteDateTime = DateTime() + m.giDécalageAvecLeServeur

  Return m.lvPucetteDateTime
Endfunc



Luc

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000012624
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3