ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: SELECT ... Count(distinct ...), Count(distinct ...) ... : DISTINCT is invalid.   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

jeu. 01 août 2013, 12h15

FoxInCloud (Th. Nivelet)
France France

atoutfox.public.association

Re: SELECT ... Count(distinct ...), Count(distinct ...) ... : DISTINCT is invalid.

Merci Me Gregory,

Le mer. 31 juillet 2013, 19h19 Gregory a écrit :
>
> > - la disparition de parent m'interpelle
>
> Si l'integrite referencielle y est, pas besoin de passer par le parent

Yes, l'un ou l'autre idem
Je garde la pk car en pratique le parent est plutôt filtré sur des clés naturelles

> > - je ne trouve pas d'outer join
>
> mais un full join est un outer join ( comme left join et right join)

bon sang, mais c'est bien sûr !

> > - pk cast(... as B(0)) et non cast(... as I)
>
> parce que le count() frabrique un num(11,0) et un int est un peu plus que
> num(9,0)
> et B(0) est a peu pres num(16,0)

Yes, tu me l'apprends, merci


Le prg de test débarrassé de ses dépendances et intégrant la solution de Me Gregory (OK of course):
* Teste diverses façons d'obtenir le nombre d'enregistrements de plusieurs tables enfant d'une table parent

* Cas d'application typique: synthèse d'un élément de haut niveau (client par exemple)
*  mentionnant son nombre de commandes, de factures, de contacts, etc.

* Les cas de test ci-dessous sont les tentatives successives pour obtenir le bon résultat

* Aucune dépendance: vous pouvez exécuter tel quel, par exemple en copiant-collant le code dans un .prg

CreateData() && ci-dessous

dimension aResult[1] && résultat d'un test (... into array aResult)

clear
cResult = '' && l'ajout à _cliptext est différé, comme asynchrone ...
_Tally = 0

on error = AddToResult(Message())

AddToResult('pk, count(child1):')
select ;
    parent.pk;
  , Count(child1.data) as child1_cnt;
  from parent;
    join child1 on parent.Pk = child1.fk;
    join child2 on parent.Pk = child2.fk;
  group by 1;
  into array aResult
AddToResult(@m.aResult)

AddToResult('pk, count(child2):')
select ;
    parent.pk;
  , Count(child2.data) as child2_cnt;
  from parent;
    join child1 on parent.Pk = child1.fk;
    join child2 on parent.Pk = child2.fk;
  group by 1;
  into array aResult
AddToResult(@m.aResult)


AddToResult('pk, count(child1), count(child2):')
select ;
    parent.pk;
  , Count(child1.data) as child1_cnt;
  , Count(child2.data) as child2_cnt;
  from parent;
    join child1 on parent.Pk = child1.fk;
    join child2 on parent.Pk = child2.fk;
  group by 1;
  into array aResult
AddToResult(@m.aResult)

AddToResult('pk, count(distinct child1):')
select ;
    parent.pk;
  , Count(distinct child1.data) as child1_cnt;
  from parent;
    join child1 on parent.Pk = child1.fk;
    join child2 on parent.Pk = child2.fk;
  group by 1;
  into array aResult
AddToResult(@m.aResult)

AddToResult('pk, count(distinct child2):')
select ;
    parent.pk;
  , Count(distinct child2.data) as child2_cnt;
  from parent;
    join child1 on parent.Pk = child1.fk;
    join child2 on parent.Pk = child2.fk;
  group by 1;
  into array aResult
AddToResult(@m.aResult)


AddToResult('pk, count(distinct child1), count(distinct child2):')
select ;
    parent.pk;
  , Count(distinct child1.data) as child1_cnt;
  , Count(distinct child2.data) as child2_cnt;
  from parent;
    join child1 on parent.Pk = child1.fk;
    join child2 on parent.Pk = child2.fk;
  group by 1;
  into array aResult
AddToResult(@m.aResult)

AddToResult('Solution de Me Gregory (http://www.atoutfox.org/nntp.asp?ID=0000012686):')
select ;
    parent.pk;
  , cast(nvl(Q1.child1_cnt, 0) as B(0)) as child1_cnt;
  , cast(nvl(Q2.child2_cnt, 0) as B(0)) as child2_cnt;
  from parent;
    full join (;
        select;
          fk;
        , count(distinct data) as child1_cnt ;
        from child1;
        group by 1;
      ) Q1 on (parent.pk == Q1.fk);
    full join (;
        select;
          fk;
        , count(distinct data) as child2_cnt ;
        from child2 ;
        group by 1;
      ) Q2 on (parent.pk == Q2.fk);
  into array aResult
AddToResult(@m.aResult)

on error

_cliptext = m.cResult
return m.cResult

#if .F. && collé de m.cResult ci-dessus
01/08/2013 11:59:10
pk, count(child1):
1,12
2,20
KO

pk, count(child2):
1,12
2,20
KO

pk, count(child1),  count(child2):
1,12,12
2,20,20
KO

pk, count(distinct child1):
1,3
2,4
OK

pk, count(distinct child2):
1,4
2,5
OK

pk, count(distinct child1), count(distinct child2):
SQL: DISTINCT is invalid.
KO

Solution de Me Gregory (http://www.atoutfox.org/nntp.asp?ID=0000012686):
1,3,4
2,4,5
OK

#endif

* ---------------------------------------------------------
procedure CreateData

create curs parent (pk I)
insert into parent values (1)
insert into parent values (2)

create curs child1 (fk I, data I)
insert into child1 values (1, 1)
insert into child1 values (1, 2)
insert into child1 values (1, 3)

insert into child1 values (2, 1)
insert into child1 values (2, 2)
insert into child1 values (2, 3)
insert into child1 values (2, 4)

create curs child2 (fk I, data I)
insert into child2 values (1, 1)
insert into child2 values (1, 2)
insert into child2 values (1, 3)
insert into child2 values (1, 4) && un enr. de + que child1

insert into child2 values (2, 1)
insert into child2 values (2, 2)
insert into child2 values (2, 3)
insert into child2 values (2, 4)
insert into child2 values (2, 5)

endproc

* ---------------------------------------------------------
function AddToResult
lparameters result && @
external array result

#define CRLF  Chr(13)+Chr(10)

local elt, row, col, s, lines[1], line
s = ''

do case

case Type('result', 1) == 'A' and Alen(m.result) > 1 && Select result
  for elt = 1 to Alen(m.result)
    row = Asubscript(result, m.elt, 1)
    col = Asubscript(result, m.elt, 2)
    s = m.s;
     + Iif(m.col = 1;
       , Iif(m.row = 1;
         , '';
         , CRLF;
         );
       , ',';
       );
     + Transform(m.result[m.elt])
  endfor

case Vartype(m.result) == 'C' && header or error

  s = Iif(_Tally > 0;
    , CRLF; && header
    , ''; && error
    );
    + Iif(Empty(m.cResult), Ttoc(Datetime())+CRLF, '');
    + m.result

  _Tally = 0
  dimension aResult[1]
  aResult = .F.

endcase

* echo
for line = 1 to ALines(lines, m.s)
  ? lines[line]
endfor

cResult = m.cResult;
  + m.s;
  + Iif(Empty(m.s), '', CRLF)

endproc





Permalink : http://www.atoutfox.org/nntp.asp?ID=0000012690
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3