ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Append blank sur vue distante et récupération de l'id autoincrémenté   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

lun. 23 septembre 2013, 11h53
OlivierH
atoutfox.public.association

Re: Append blank sur vue distante et récupération de l'id autoincrémenté

Hello Luc


Voici une méthode qui génère en programmation un insert sql

Il faut lui envoyer l'object provenant du scatter name Object, et le nom
de la table

J'ai la meme chose pour l'update, et je me sers de cela pour sql server,
peut etre qu'il faut convertir pour Postgres.


Olivier,


*===========================================================
* Methode qui nous permet de composer par programmation une requete
* Sql Insert grâce à l'objet provenant d'un scatter Object
*
* important de ne pas avoir le set point "," en virgule car cause probleme
* dans la creation de la requete
*===========================================================
LPARAMETERS oData, cTable
LOCAL cFieldList as String,cValueList as String, nFields as Integer, x
as Integer, cField as String, cType as String
Local vValue as Variant, cValue as String, cSetPoint as String,oDATE as
_DATE of CLASS_UTIL.vcx
Local array laFields(1)

m.cSetPoint = Set("Point")
m.oDATE = newObject("_DATE","CLASS_UTIL.vcx")
Set Point To "."

m.cSQL = "INSERT " + m.cTable
m.cFieldList = ""
m.cValueList = ""

m.nFields = AMEMBERS(m.laFields,m.oData)
FOR m.x=1 TO m.nFields
m.cField = m.laFields[m.x]

* Pour exclure le TimeStamp
IF UPPER(m.cField) = "TIMESTAMP_COLUMN" && ou autre nom
LOOP
ENDIF

m.cFieldList = m.cFieldList + m.cField + ","
m.cType = Alltr(TYPE("m.oData."+m.laFields[m.x]))
DO CASE
CASE m.cType $ "CMV"
m.vValue = STRTRAN(EVAL("m.oData."+m.cField),"'","''")
m.vValue = STRTRAN(m.vValue,";"," ")
m.vValue = STRTRAN(m.vValue,"\"," ")
&& voir si on garde pour SqlServer ou si ca marche sans
m.vValue = STRTRAN(m.vValue,chr(10)," ")
m.vValue = Alltr(m.vValue)
m.cValue = [']+m.vValue+[']
CASE m.cType $ "NYBFI"
m.cValue = TRANSFORM(EVAL("m.oData."+m.cField))
CASE m.cType == "L"
m.cValue = IIF(EVAL("m.oData."+m.cField),'1','0')
CASE m.cType == "D"
m.vValue = m.oDATE.GetCorrectDate(EVAL("m.oData."+m.cField))
m.cValue = [']+IIF(EMPTY(m.vValue),"",DTOC(m.vValue))+[']
CASE m.cType == "T"
m.vValue = m.oDATE.GetCorrectDate(EVAL("m.oData."+m.cField))
m.cValue = [']+IIF(EMPTY(m.vValue),"",TTOC(m.vValue))+[']
CASE m.cType =="Q" && varbinary
* cas particulier en binaire directement
m.vValue = EVAL("m.oData."+m.cField)
m.cValue = iif(Len(m.vValue)>1,"0x" + TRANSFORM(m.m.vValue),[''])
OTHERWISE
m.cValue = ['?']
*=MESSAGEBOX("a traiter Transformer type="+TYPE("t_champ"))
ENDCASE

m.cValueList = m.cValueList + m.cValue + ","
ENDFOR

IF EMPTY(m.cFieldList) OR EMPTY(m.cValueList)
m.cSQL = ""
ELSE
m.cFieldList = SUBSTR(m.cFieldList,1,LEN(m.cFieldList) - 1)
m.cValueList = SUBSTR(m.cValueList,1,LEN(m.cValueList) - 1)
m.cSQL = m.cSQL + " (" + m.cFieldList + ") VALUES (" + m.cValueList
+ ")"
ENDIF

m.oDATE = null
Set Point To (m.cSetPoint)

RETURN m.cSQL







Le 23/09/2013 07:48, Luc a écrit :
> Merci Gilles
>
> J'espérais pouvoir faire l'impasse su la réécriture de beaucoup de lignes de code, mais je vois que ce n'est pas possible.
>
> Tant pis
>
> Luc
>
>
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000012889
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3