ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Append blank sur vue distante et récupération de l'id autoincrémenté   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

mar. 24 septembre 2013, 19h15

GLS
France France

atoutfox.public.association

Re: Append blank sur vue distante et récupération de l'id autoincrémenté

Bonjour Luc,

Dans le paramétrage des vues, l'ID/PK n'est pas mis à jour donc il n'y a aucun conflit, ce d'autant que mes vues sont toujours en SendUpdate = .F. pour éviter les mises à jours intempestives.

du concret :
*////////////////////////////////*
* Structure de la vue d'exemple *
*////////////////////////////////*
*!*  SELECT Dico.*;
*!*   FROM ;
*!*       dico Dico;
*!*   WHERE  Dico.code_ana =  ?cCodeAna ;
*!*   ORDER BY Dico.ordre_res

*!*  DBSetProp(ThisView,"View","SendUpdates",.F.)
*!*  DBSetProp(ThisView,"View","BatchUpdateCount",1)
*!*  DBSetProp(ThisView,"View","CompareMemo",.T.)
*!*  DBSetProp(ThisView,"View","FetchAsNeeded",.F.)
*!*  DBSetProp(ThisView,"View","FetchMemo",.T.)
*!*  DBSetProp(ThisView,"View","FetchSize",100)
*!*  DBSetProp(ThisView,"View","MaxRecords",-1)
*!*  DBSetProp(ThisView,"View","Prepared",.F.)
*!*  DBSetProp(ThisView,"View","ShareConnection",.T.)
*!*  DBSetProp(ThisView,"View","AllowSimultaneousFetch",.F.)
*!*  DBSetProp(ThisView,"View","UpdateType",1)
*!*  DBSetProp(ThisView,"View","UseMemoSize",255)
*!*  DBSetProp(ThisView,"View","Tables","dico")
*!*  DBSetProp(ThisView,"View","WhereType",3)

*!*  DBSetProp(ThisView+".cle","Field","DataType","I")
*!*  DBSetProp(ThisView+".cle","Field","UpdateName","dico.idpk")
*!*  DBSetProp(ThisView+".cle","Field","KeyField",.T.)
*!*  DBSetProp(ThisView+".cle","Field","Updatable",.F.)

*!*  DBSetProp(ThisView+".ordre_res","Field","DataType","C(3)")
*!*  DBSetProp(ThisView+".ordre_res","Field","UpdateName","dico.ordre_res")
*!*  DBSetProp(ThisView+".ordre_res","Field","KeyField",.F.)
*!*  DBSetProp(ThisView+".ordre_res","Field","Updatable",.T.)

*!*  DBSetProp(ThisView+".code_ana","Field","DataType","C(6)")
*!*  DBSetProp(ThisView+".code_ana","Field","UpdateName","dico.code_ana")
*!*  DBSetProp(ThisView+".code_ana","Field","KeyField",.F.)
*!*  DBSetProp(ThisView+".code_ana","Field","Updatable",.T.)

*!*  DBSetProp(ThisView+".code_res","Field","DataType","C(6)")
*!*  DBSetProp(ThisView+".code_res","Field","UpdateName","dico.code_res")
*!*  DBSetProp(ThisView+".code_res","Field","KeyField",.F.)
*!*  DBSetProp(ThisView+".code_res","Field","Updatable",.T.)

*!*  DBSetProp(ThisView+".code_ope","Field","DataType","I")
*!*  DBSetProp(ThisView+".code_ope","Field","UpdateName","dico.code_ope")
*!*  DBSetProp(ThisView+".code_ope","Field","KeyField",.F.)
*!*  DBSetProp(ThisView+".code_ope","Field","Updatable",.T.)

*!*  DBSetProp(ThisView+".dateheure","Field","DataType","T")
*!*  DBSetProp(ThisView+".dateheure","Field","UpdateName","dico.dateheure")
*!*  DBSetProp(ThisView+".dateheure","Field","KeyField",.F.)
*!*  DBSetProp(ThisView+".dateheure","Field","Updatable",.T.)

*!*  DBSetProp(ThisView+".inactif","Field","DataType","I")
*!*  DBSetProp(ThisView+".inactif","Field","UpdateName","dico.inactif")
*!*  DBSetProp(ThisView+".inactif","Field","KeyField",.F.)
*!*  DBSetProp(ThisView+".inactif","Field","Updatable",.T.)



*/////////////////////////////////////////*
* EXEMPLE D'UTILISATION *
* TOUTES MES VUES SONT "SendUpdates"=.F. *
*/////////////////////////////////////////*

* La vue est préalablement ouverte avec ou sans un requry() pour y charger du contenu. Des append blank ont été effectués dans celle-ci avec des replaces

iFinChange=AFIELDS(laChange,'v_dico') && met dans le tableau laChange la liste des champs de la vue
SELECT v_dico
SCAN
  SELECT v_dico
  cCodeResOrig=v_dico.code_res
  IF EMPTY(v_dico.idpk) && clé idpk vide suite à un append blank
    REPLACE v_dico.idpk WITH ins_table_inc(ALIAS(),'dico')
  ELSE
    IF EMPTY(v_dico.inactif)
      FOR iCount=1 TO m.iFinChange
        IF GETFLDSTATE(m.laChange[m.iCount,1],'v_dico')>1
          =maj_table(ALIAS(),.F.) && si au moins un champ a son contenu de changé
          EXIT
        ENDIF
      ENDFOR
    ELSE
      IF GETFLDSTATE('inactif','v_dico')>1 && si inactif alors enregistrement directe
        =maj_table(ALIAS(),.F.)
      ENDIF
    ENDIF
  ENDIF
ENDSCAN


*****************************************************************************
*                 Procedure: ins_table_inc
*****************************************************************************
* cette procédure met à jour l'enregistrement de la vue p_alias sur la table autoincrément p_table
* en activant d'abord la propriété "sendupdates" puis en mettant à jour l'enregistrement en cours
* si la mise à jour est echouée, la procédure retourne -1,
* sinon elle retourne le N° de la clé primaire autoindexation de la table p_table
PROCEDURE ins_table_inc
  LPARAMETERS p_inc_alias, p_inc_table
  LOCAL iRetour AS INTEGER , iSelect AS INTEGER , cClePrim AS STRING , cSql AS STRING , cValeur AS STRING
  iRetour = -1
  IF PCOUNT()>1
    iSelect = SELECT(0)
    cClePrim = "idpk"
    p_inc_alias=LOWER(ALLTRIM(m.p_inc_alias))
    SELECT (m.p_inc_alias)
    cSql = genere_insert(m.p_inc_alias,m.p_inc_table, m.cClePrim)
    IF sqlEmet(m.cSql,'c_sql')>0
      cValeur='c_sql.'+m.cClePrim
      iRetour=&cValeur
    ENDIF
    USE IN SELECT('c_sql')
    SELECT (m.iSelect)
  ENDIF
  RETURN m.iRetour
ENDPROC

* Fonction de génération du code INSERT SQL a partir de la structure et des datas d'un alias d'après le code de Francis Faure
FUNCTION genere_insert(p_alias AS STRING, p_table AS STRING, p_clepk AS STRING, p_pasretourpk AS Boolean) AS STRING
  LOCAL ARRAY la_Champs[1,18]
  LOCAL ARRAY la_table[1,18]
  LOCAL li_nombre_de_champs AS INTEGER
  LOCAL li_i AS INTEGER
  LOCAL c_sqlinsert AS STRING
  LOCAL ls_champ AS STRING, ls_liste AS STRING
  c_sqlinsert=''
  IF USED(m.p_alias)
    ls_liste=CURSORGETPROP("UpdatableFieldList",m.p_alias)
    li_nombre_de_champs = AFIELDS(la_Champs)
    c_sqlinsert = "INSERT INTO "+LOWER(m.p_table)+" ("
    FOR li_i=1 TO m.li_nombre_de_champs
      IF m.la_Champs[li_i, 2]="G" OR ALLTRIM(LOWER(m.la_Champs[li_i,1]))==ALLTRIM(m.p_clepk) OR LOWER(m.la_Champs[li_i,1])="dateheure" OR LOWER(m.la_Champs[li_i,1])="inactif" OR !UnChamptable(m.p_alias,m.la_Champs[li_i,1],m.ls_liste)&& ignorer champ/colonne dateheure et inactif
        LOOP
      ENDIF
      c_sqlinsert = m.c_sqlinsert + " "+LOWER(m.la_Champs[li_i, 1]) + ","
    NEXT
    IF RIGHT(m.c_sqlinsert,1)=","
      * Suppression du dernier caractère si c'est ","
      c_sqlinsert=LEFT(m.c_sqlinsert,LEN(m.c_sqlinsert)-1)
    ENDIF
    c_sqlinsert = m.c_sqlinsert + ") VALUES ("
    FOR li_i=1 TO m.li_nombre_de_champs
      IF m.la_Champs[li_i, 2]="G" OR ALLTRIM(LOWER(m.la_Champs[li_i,1]))==ALLTRIM(m.p_clepk) OR LOWER(m.la_Champs[li_i,1])="dateheure" OR LOWER(m.la_Champs[li_i,1])="inactif" OR !UnChamptable(m.p_alias,m.la_Champs[li_i,1],m.ls_liste) && ignorer champ/colonne dateheure et inactif
        LOOP
      ENDIF
      * Remplacer les dates vides par .NULL.
      ls_champ = EVALUATE(la_Champs[li_i, 1])
      IF m.la_Champs[li_i, 2]='D' OR m.la_Champs[li_i, 2]='T'
        IF EMPTY(m.ls_champ)
          ls_champ=.NULL.
        ENDIF
      ENDIF
      c_sqlinsert = m.c_sqlinsert +" "+ transformer(m.ls_champ, m.la_Champs[li_i, 6])+","
    NEXT
    IF RIGHT(m.c_sqlinsert,1)=","
      * Suppression du dernier caractère si c'est ","
      c_sqlinsert=LEFT(m.c_sqlinsert,LEN(m.c_sqlinsert)-1)
    ENDIF
    c_sqlinsert = m.c_sqlinsert + IIF(m.p_pasretourpk,")",") RETURNING "+ALLTRIM(m.p_clepk))
  ENDIF
  RETURN m.c_sqlinsert
ENDFUNC


* Fonction d'émission des commandes SQL auprès du SGBDR
* Retourne -2 si action impossible ou erreur de connexion
* Retourne -1 si curseur p_curseur non créé ou si action sans curseur impossible
* retourne le nombre d'enregistrements du curseur p_curseur, ou le résultat de l'action sans curseur
FUNCTION sqlEmet(p_Action,p_curseur,p_no_use_curseur)
  LOCAL iRetour AS INTEGER , iDebut AS INTEGER
  iRetour=-2
  IF VARTYPE(m.p_Action)="C"
    IF !m.p_no_use_curseur
      iRetour=SQLEXEC(m.nPgConnect, m.p_Action,m.p_curseur) && m.PgConnect contient le handle de la connexion postgresl
    ELSE
      iRetour=SQLEXEC(m.nPgConnect, m.p_Action)
    ENDIF
    DO CASE
      CASE !m.p_no_use_curseur AND m.iRetour=-1
        * Erreur d'exécution ordre SQL sans création d'un curseur VFP en retour
        iRetour=-2
      CASE m.p_no_use_curseur AND m.iRetour<1
        iRetour=-2
        * Erreur d'exécution ordre SQL avec création d'un curseur VFP en retour
      OTHERWISE
        IF !m.p_no_use_curseur AND USED(m.p_curseur)
          iRetour=RECCOUNT(m.p_curseur)
        ENDIF
    ENDCASE
  ENDIF
  RETURN m.iRetour
ENDFUNC


* Fonction de mise à jour du contenu d'une vue vers les tables parents
* p_vue contient le nom de la vue
* p_tous = .T. tous les enregistrements de la vue sont mis à jour. .F.  seul l'enregistrement courant est mis à jour
FUNCTION maj_table
  LPARAMETERS p_vue, p_tous
  LOCAL lRetour AS Boolean , iSelect AS INTEGER
  IF PCOUNT()>0
    * p_vue contient le nom de la vue servant à mettre à jour les tables
    p_vue=LOWER(ALLTRIM(m.p_vue))
    * p_tous .T. tous les enregistrements sont mis à jour, .F. seul l'enregistrement courant est mis à jour
    iSelect=SELECT(0)
    SELECT (m.p_vue)
    IF !CURSORSETPROP("sendupdates", .T., m.p_vue)
      &&<ERREUR>DROIT DE MISE A JOUR CURSEUR IMPOSSIBLE
    ELSE
      lRetour = TABLEUPDATE(IIF(m.p_tous,1,0),.T.,m.p_vue)
      IF !m.lRetour
        &&<ERREUR>MISE A JOUR ENREGISTREMENT IMPOSSIBLE
        =TABLEREVERT(.T.,m.p_vue)
      ENDIF
      =CURSORSETPROP("sendupdates", .F., m.p_vue)
    ENDIF
    SELECT (m.iSelect)
  ENDIF
  RETURN m.lRetour
ENDFUNC


Gilles

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000012907
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3