ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Modification de la date système   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

sam. 11 janvier 2014, 15h45
Gregory Adam
Belgique Belgique

atoutfox.public.association

Re: Modification de la date système

Bonjour,

L'utilisateur est libre de changer le temps de son ordi

Je ne suis pas convaincu qu'il faut employer la date/heure pour determiner s'il faut activer l'appli


Neanmoins, on peut utiliser GetTickCount() http://msdn.microsoft.com/en-us/library/windows/desktop/ms724408(v=vs.85).aspx

- donne le nombre de ms depuis le demarrage de l'ordi
- est remis a zero après 49.7 jours ( que 4 bytes). Possible d'utiliser GetTickCount64()

Une spimple demo qui permet de changer l'heure du systeme entre deux affichages

*_______________________________________________________________________________
function do_it()


  local myTime

  myTime = createobject('MyTime')

  ?datetime(), m.mytime.GetDateTime()

  wait window 'change the system time and hit any key'
  ?datetime(), m.mytime.GetDateTime()

endfunc
*_______________________________________________________________________________

define class MyTime as relation

  protected TicksInitial
  protected StartDateTime

protected function init()

  this.TicksInitial = m.this.GetTickCount()
  this.StartDateTime = datetime()


endfunc
protected function GetTickCount()

  local n
  n = GetTickCount()

  return iif(m.n >= 0, m.n, m.n + 0xffffffff)

endfunc
function GetDateTime()
  return m.this.StartDateTime + (m.this.GetTickCount() - m.this.TicksInitial)/1000
endfunc
enddefine
*_______________________________________________________________________________
function GetTickCount()

  declare long GetTickCount in kernel32
  return GetTickCount()
endfunc
*_______________________________________________________________________________


Journal

Francis Faure pense que ce message est la bonne réponse ou qu'il est utile
gardener pense que ce message est la bonne réponse ou qu'il est utile
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000013612
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3