ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Modifier une cellule d'un Grig   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

sam. 15 février 2014, 14h18

Luc
France France

atoutfox.public.association

Re: Modifier une cellule d'un Grig

Un petit programme de démo :

Local loFrm As Form, loGrille as Grid
Create Cursor MonCurseur (iId I AutoInc, cLibelle C(254), iCouleur I, cFontFormat C(5))
Insert Into MonCurseur (cLibelle, iCouleur, cFontFormat) Values ("Rouge", Rgb(255, 0, 0), "I")
Insert Into MonCurseur (cLibelle, iCouleur, cFontFormat) Values ("Vert", Rgb(0, 255, 0), "G")
Insert Into MonCurseur (cLibelle, iCouleur, cFontFormat) Values ("Bleu", Rgb(0, 0, 255), "IG")
Insert Into MonCurseur (cLibelle, iCouleur, cFontFormat) Values ("Noir", Rgb(0, 0, 0), "")
Insert Into MonCurseur (cLibelle, iCouleur, cFontFormat) Values ("Blanc", Rgb(255, 255, 255), "")
Go Top In MonCurseur

m.loFrm = CreateObject("Form")
m.loFrm.AddObject("MaGrille", "Grid")
m.loGrille = m.loFrm.MaGrille
m.loGrille.Visible = .T.
m.loGrille.Move(0, 0, m.loFrm.Width, m.loFrm.Height)
m.loGrille.Anchor = 1 + 2 + 4 + 8
m.loGrille.RecordSource = "MonCurseur"
m.loGrille.Column2.DynamicBackColor = "iCouleur"
m.loGrille.Column2.DynamicFontItalic = "EstItalique(cFontFormat)"
m.loGrille.Column2.DynamicFontBold = "EstGras(cFontFormat)"
m.loFrm.Show(1)

Function EstItalique
  LPARAMETERS tcFontFormat
  Return "I" $ m.tcFontFormat
Endfunc
Function EstGras
  LPARAMETERS tcFontFormat
  Return "G" $ m.tcFontFormat
EndFunc


Luc

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000013921
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3