ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: COPY de gros fichiers avec suivi de la progression   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

jeu. 14 août 2014, 10h08
Gregory
atoutfox.public.association

Re: COPY de gros fichiers avec suivi de la progression

> valeurs négative pour la taille totale et l'encours de copie

ctobin prend de vrais int, cad que si le bit de gauche est ON cela est une
valeur negative
Il faut le traiter comme un unsigned

eg: 0xffffffff est -1 en signed int

en unsigned c'est 2^32-1

donc si on a -1 il faut ajouter 2^32 pour arriver a 2^32 -1


______
Gregory
______
"Eto" wrote in message news:lsfho1$2j3m$1@news.niouzes.net...

Le forum sur le site AtouFox semble planté, je reposte ici pour la 3ème
fois, désolé si mes messages arrivent après !!

donc,

je veux copier des fichiers avec suivi de progression.

Si j'utilise FOPEN(),FREAD(),FWRITE() etc, Fox me renvoie un fichier
trop important (Par exemple fichier de 3 go) et la copie ne se finalise
pas.

si j'utilise COPYFILEEX(), la copie se fait bien mais la progression
commence à ne plus être cohérente à partir de 2 Go. cela me renvoie des
valeurs négative pour la taille totale et l'encours de copie.

Auriez-vous une idée ?

Merci d'avance.

Je poste le code utilisé pour les experts qui y verraient le problème !


lParameters _from,_to

Declare INTEGER CopyFileEx in win32api;
STRING lpExistingFileName,;
STRING lpNewFileName,;
LONG lpProgressRoutine,;
STRING lpData,;
INTEGER@ pbCancel,;
INTEGER dwCopyFlags;

cfHook = CreateObject("CopyFileCallback")
bCancel = 0
=CopyFileEx(_from,_to, cfHook.ProcAddress, "Progress :", @bCancel, 0)

Define Class CopyFileCallback as Callback
*!* DWORD CALLBACK CopyProgressRoutine(
*!* __in LARGE_INTEGER TotalFileSize,
*!* __in LARGE_INTEGER TotalBytesTransferred,
*!* __in LARGE_INTEGER StreamSize,
*!* __in LARGE_INTEGER StreamBytesTransferred,
*!* __in DWORD dwStreamNumber,
*!* __in DWORD dwCallbackReason,
*!* __in HANDLE hSourceFile,
*!* __in HANDLE hDestinationFile,
*!* __in_opt LPVOID lpData
*!* )
*********** Total parameters size = 52 Bytes
Procedure Init
Return DoDefault(52)
EndProc

Procedure Callback
Lparameters sParams
local TotalFileSize,; && 8 bytes
TotalBytesTransferred, ; && 8 bytes
StreamSize, ; && 8 bytes
StreamBytesTransferred, ; && 8 bytes
StreamNumber, ; && 4 bytes
CallbackReason, ; && 4 bytes
SourceFile, ; && 4 bytes
DestinationFile, ; && 4 bytes
lpData && 4 bytes


TotalFileSize =
CToBin(Substr(sParams,1,4),"4RS")+CToBin(Substr(sParams,5,4),"4RS")*0x100000000
TotalBytesTransferred =
CToBin(Substr(sParams,9,4),"4RS")+CToBin(Substr(sParams,13,4),"4RS")*0x100000000
StreamSize =
CToBin(Substr(sParams,17,4),"4RS")+CToBin(Substr(sParams,21,4),"4RS")*0x100000000
StreamBytesTransferred =
CToBin(Substr(sParams,25,4),"4RS")+CToBin(Substr(sParams,29,4),"4RS")*0x100000000
StreamNumber = CToBin(Substr(sParams,33,4),"4RS")
CallbackReason = CToBin(Substr(sParams,37,4),"4RS")
SourceFile = CToBin(Substr(sParams,41,4),"4RS")
DestinationFile = CToBin(Substr(sParams,45,4),"4RS")
lpData = CToBin(Substr(sParams,49,4),"4RS")

Activate screen
If CallbackReason=1
EndIf
&&&&&&&&&&&&&&&&&&&&& C'est ici que je constate qu'à partir de 2 go
cela me retourne des valeurs négatives...

? StreamBytesTransferred,StreamSize

return 0 && PROGRESS_CONTINUE
EndProc
ENDDEFINE

Define Class Callback as Form
oRefForm=null
ProcAddress = 0
hHeap = 0

Procedure Init
Lparameters tnParamSize
Declare LONG GetModuleHandleA In WIN32API String
Declare LONG GetProcAddress In WIN32API LONG hModule, String
procname
Declare LONG HeapAlloc In WIN32API LONG hHeap, LONG dwFlags, LONG
dwBytes
Declare LONG HeapCreate In WIN32API LONG dwFlags, LONG dwBytes,
LONG dwMaxBytes


#define WM_USERCALLBACK 0x400+700

If Vartype(tnParamSize)#"N"
tnParamSize = 0
EndIf
Local pfnSendMessage,hModule
hModule = GetModuleHandleA("user32.dll")
pfnSendMessage=GetProcAddress(hModule,"SendMessageA")

*Emit code
Local sCode
*Enter
sCode = Chr(0x55) && push ebp
sCode = sCode + Chr(0x89) + Chr(0xE5) && mov ebp, esp
*Read data
If tnParamSize=0
sCode = sCode + Chr(0x68) + BinToC(0,"4rs") && push 0 : lParam
- ptr to params
Else
sCode = sCode + Chr(0x89) + Chr(0xE8) && mov eax,ebp
sCode = sCode + Chr(0x83) + Chr(0xC0) + Chr(0x08) && add eax,8
sCode = sCode + Chr(0x50) && push eax : lParam - ptr to
params
EndIf
*Push general parameters
sCode = sCode + Chr(0x68) + BinToC(tnParamSize,"4rs") && push
wParam - param size
sCode = sCode + Chr(0x68) + BinToC(WM_USERCALLBACK,"4rs") &&
push nMsg
sCode = sCode + Chr(0x68) + BinToC(this.hWnd,"4rs") && push hWnd
*Send message
sCode = sCode + Chr(0xB8) + BinToC(pfnSendMessage,"4rs") && move
eax, procSendMessage
sCode = sCode + Chr(0xFF) + Chr(0xD0) && call eax
*Return
sCode = sCode + Chr(0xC9) && leave
If tnParamSize = 0
sCode = sCode + Chr(0xC3) && ret
Else
sCode = sCode + Chr(0xC2) + BinToC(tnParamSize,"2RS") && ret
tnParamSize
EndIf

*Allocate memory for code
#define HEAP_CREATE_ENABLE_EXECUTE 0x00040000
this.hHeap =
HeapCreate(HEAP_CREATE_ENABLE_EXECUTE,Len(sCode),Len(sCode))
this.ProcAddress = HeapAlloc(this.hHeap,0,Len(sCode))
*Write emitted code
sys(2600,this.ProcAddress,Len(sCode),sCode)
BindEvent(this.HWnd,WM_USERCALLBACK,this,"CallbackEvent")
EndProc

Procedure CallbackEvent
Lparameters hWnd,uMsg,wParam,lParam
Local sParamData
If m.wParam>0
sParamData=Sys(2600,lParam,wParam)
Else
sParamData = ""
EndIf

Return this.Callback(sParamData)
EndProc

Procedure Callback
Lparameters sParamData
EndProc

Procedure Destroy
UnBindEvents(this)
Declare LONG HeapDestroy In WIN32API LONG hHeap
HeapDestroy(this.hHeap)
EndProc
ENDDEFINE
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000014999
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3