ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Editeur HTML de Fred A en contrib, interlignage   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

sam. 29 novembre 2014, 00h57
ybenam
Algérie Algérie

atoutfox.public.association

Re: Editeur HTML de Fred A en contrib, interlignage

Merci à FoxinCloud pour le lien.

L'application utilise l'activeX shell.explorer.2 (browser internet explorer pour vfp forms).
En mode d'édition (designmode="on") les sauts de lignes sont natifs et sont générés automatiquement (balise <p></p> à chaque retour de chariot)
toutefois le code présente quelques problèmes
-il ne fonctionne que sur IE (Firefox ne lit pas les images par ex. (pour des problèmes de syntaxe)
-le bouton "save" ne sauvegarde pas le htm|html créé (cela donne une page web vide chez moi).
-J'avais développé une application de ce genre dans le passé.Peut être que je la posterai un jour après re vérification chez Atoutfox.
tu peux télécharger ces applications dans le même genre:

http://www.nirsoft.net/utils/html_doc_edit.html
http://www.microsoft.com/en-us/download/details.aspx?id=8956
http://msdn.microsoft.com/en-us/library/dd464638%28v=vs.85%29.aspx
ce dernier lien présente qqes problèmes (fichier hta).

cela peut te lancer pour créer un "html editor" assez complet et sous VFP.

Essaie aussi ce code qui peut te servir (clique sur ? pour l'aide):
Publi yform,yrep,oo
m.yrep= Addbs(Justpath(Sys(16,1)))

yform=Newobject("ybrowser_edit")
yform.Show
Return
*
Define Class ybrowser_edit As Form
  Height = 495
  Width = 711
  ShowWindow = 2
  AutoCenter = .T.
  Caption = "Editable Browser"
  ystr = .F.
  afile = .F.
  Name = "form1"

  Add Object obrowser As OleControl With ;
    oleclass="shell.explorer.2" , ;
    Top = 12, ;
    Left = 12, ;
    Height = 408, ;
    Width = 684, ;
    Anchor = 15, ;
    Name = "obrowser"


  Add Object command1 As CommandButton With ;
    Top = 444, ;
    Left = 433, ;
    Height = 37, ;
    Width = 121, ;
    Anchor = 768, ;
    Caption = "Edit", ;
    Name = "Command1"


  Add Object command2 As CommandButton With ;
    Top = 444, ;
    Left = 289, ;
    Height = 37, ;
    Width = 121, ;
    Anchor = 768, ;
    Caption = "Load ...", ;
    Enabled = .F., ;
    Name = "Command2"


  Add Object image1 As Image With ;
    Anchor = 768, ;
    Picture = (Home()+"graphics\icons\win95\explorer.ico"), ;
    Stretch = 2, ;
    Height = 37, ;
    Left = 157, ;
    MousePointer = 15, ;
    Top = 444, ;
    Width = 49, ;
    Name = "Image1"


  Add Object label1 As Label With ;
    AutoSize = .T., ;
    FontBold = .T., ;
    FontSize = 28, ;
    Anchor = 768, ;
    BackStyle = 0, ;
    Caption = "?", ;
    Height = 47, ;
    Left = 229, ;
    MousePointer = 15, ;
    Top = 442, ;
    Width = 25, ;
    ForeColor = Rgb(0,255,0), ;
    Name = "Label1"


  Procedure Init
  Thisform.SetAll('mousepointer',15,"commandbutton")
  Thisform.afile=m.yrep+"test.html"
  oo=Thisform.obrowser
  oo.Navigate("ABOUT:BLANK")
  Do While oo.busy Or oo.readyState#4
  Enddo
  Endproc


  Procedure command1.Click

  Do Case
  Case This.Caption="Edit"
    This.Caption="Close"
    Thisform.ystr=oo.Document.body.innerHtml
    oo.Document.DesignMode = "on"

  Case This.Caption="Close"
    This.Caption="Edit"
    xx=oo.Document.body.innerHtml
    If ! xx==Thisform.ystr
      If Messagebox("Save the change in "+Thisform.afile+" ?",4+64,"Saving....")=6
        =Strtofile(xx,Thisform.afile)
      Endi
      oo.Document.DesignMode ="off"
      Thisform.command2.Enabled=.T.
    Endi
  Endcase
  Endproc


  Procedure command2.Click

  Thisform.afile=Getfile('htm|html')
  oo.Navigate(Thisform.afile)
  Do While oo.busy Or oo.readyState#4
  Enddo
  This.Enabled=.F.
  Endproc


  Procedure image1.Click
  Run /N explorer &yrep
  Endproc


  Procedure label1.Click
  Local m.myvar
  TEXT to m.myvar noshow
Attendre 3s pour passer les transitionnings du navigateur puis presser le bouton Edit.
Alors Internet Explorer (oBrowser) se transforme en Richtext éditeur :
on peut écrire,colorer,couper, coller (txt, img,video...).
on peut sauvegarder les modifications...
on peut charger un fichier html,htm et le modifier puis sauvegarder.
Moyennat ce principe de base , on peut créer une barre d'outils très variée pour tous les
cas d'
édition.....(syntaxe, alignement;couleurs,fontname, fontsize,presse papier, insertion
d'objets, sauvegarde..)
rightclick sur oBrowser pour avoir le menu contextuel (presse papier+source HTML...)

Comme vous pouvez le constater les interlignes à la saisie en mode EDIT sont natives
d'
Internet explorer et je ne pense pas qu'on peut changer cela....Elles sont entourées de
balises <p></p> automatiquement

ENDTEXT
Messagebox(m.myvar,0+32+4096,"Aide sommaire")
Endproc

Procedure Destroy
oo=Null
Release oo
Clea Events
Endproc

Enddefine


n'hésite pas à poser les questions sur le sujet, ce forum est fait pour cela !
Bon courage :

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000015482
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3