ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: setfocus   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

jeu. 25 décembre 2014, 12h15
ybenam
Algérie Algérie

atoutfox.public.association

Re: setfocus

Bonjour Abderrazak !
Pour répondre à ton problème voici un exemple concret de form de saisie (met le toujours modal pour accaparer la saisie et ne pas libérer le focus de la fenêtre)
tu peux installer le TABORDER manuellement ou par programmation (comme le cas ci après).
l'ordre de saisie des contrôles sur un form (textbox, editbox) est à installer au prélabale (form.init par ex.).

Publi yform
yform=Newobject("yfocus")
yform.Show(1)   &&modal
Return
*
Define Class yfocus As Form
  Height = 393
  Width = 460
  AutoCenter = .T.
  Caption = "Ordre de saisie sur controles VFP"
  Name = "Form1"

  Add Object text1 As TextBox With ;
    Height = 25, ;
    Left = 89, ;
    Top = 62, ;
    Width = 140, ;
    Name = "Text1"

  Add Object text2 As TextBox With ;
    Height = 25, ;
    Left = 92, ;
    Top = 98, ;
    Width = 140, ;
    Name = "Text2"

  Add Object text3 As TextBox With ;
    Height = 25, ;
    Left = 92, ;
    Top = 136, ;
    Width = 140, ;
    Name = "Text3"

  Add Object text4 As TextBox With ;
    Height = 25, ;
    Left = 94, ;
    Top = 180, ;
    Width = 140, ;
    Name = "Text4"

  Add Object text5 As TextBox With ;
    Height = 25, ;
    Left = 94, ;
    Top = 223, ;
    Width = 140, ;
    Name = "Text5"

  Add Object edit1 As EditBox With ;
    Height = 133, ;
    Left = 257, ;
    Top = 71, ;
    Width = 145, ;
    Name = "Edit1"

  Add Object label1 As Label With ;
    FontBold = .T., ;
    WordWrap = .T., ;
    Alignment = 2, ;
    Caption = "", ;
    Height = 84, ;
    Left = 84, ;
    Top = 321, ;
    Width = 348, ;
    BackColor = Rgb(255,255,0), ;
    Name = "Label1"


  Add Object textinfo As TextBox With ;
    FontBold = .T., ;
    Height = 25, ;
    Left = 257, ;
    Top = 284, ;
    Width = 160, ;
    ForeColor = Rgb(255,0,0), ;
    Name = "textInfo"

  Add Object text6 As TextBox With ;
    Height = 25, ;
    Left = 267, ;
    Top = 221, ;
    Width = 140, ;
    Name = "Text6"

  Add Object label2 As Label With ;
    FontBold = .T., ;
    FontItalic = .T., ;
    FontName = "Arial Black", ;
    FontSize = 20, ;
    BackStyle = 0, ;
    Caption = "TabIndex sur controles VFP", ;
    Height = 37, ;
    Left = 36, ;
    Top = 12, ;
    Width = 432, ;
    Name = "Label2"

  Add Object label3 As Label With ;
    FontBold = .T., ;
    FontItalic = .T., ;
    FontName = "Arial Black", ;
    FontSize = 20, ;
    BackStyle = 0, ;
    Caption = "TabIndex sur controles VFP", ;
    Height = 37, ;
    Left = 31, ;
    Top = 12, ;
    Width = 432, ;
    ForeColor = Rgb(255,128,0), ;
    Name = "Label3"

  Procedure my  &&juste pour voir visuellement quel contôle reçoit le focus
*--- aevent crée une matrice Events
  Aevents( myArray, 0)
*retourne l'objet concerné
  loObject = myArray[1]
  loObject.BackColor=Rgb(0,255,0)   &&couleur originale par ex.
  Thisform.textinfo.Value="Focus actuel = "+loObject.Name
  Endproc

  Procedure my1  &&change la couleu visuelle du contrôle.
*--- aevent crée une matrice Events
  Aevents( myArray, 0)
*retourne l'objet concerné
  loObject = myArray[1]
  loObject.BackColor=Rgb(255,255,255)
  Endproc

  Procedure Init
*ordre de saisie sur des contrôles donnés

  With Thisform
    .SetAll("tabStop",.T.,"textbox")
    .SetAll("tabStop",.T.,"editbox")  &&si Tabindex =.f. le contrôle est hors liste.

  *Installe l'ordre de saisie des controles ici(navigation avec  TAB key)
    .text1.TabIndex=1
    .text5.TabIndex=2
    .text2.TabIndex=3
    .text4.TabIndex=4
    .text3.TabIndex=5
    .edit1.TabIndex=6
    .text6.TabIndex=7

    For i=1 To .ControlCount
      Try  &&uniquement ici les controles qui ont Getfous
        Bindevent(.Controls(i),"Gotfocus",Thisform,"my")
        Bindevent(.Controls(i),"Lostfocus",Thisform,"my1")
      Catch
      Endtry
    Endfor

  Endwith
  Endproc

  Procedure label1.Init
  TEXT to this.caption
    Press TAB key et regarde quel contrôle de saisie est sélectionné dans le form MODAL.
    Une fois le form modal fermé , le focus est renvoyé automatiquement au form appelant
    (si le cas).
  ENDTEXT
  Endproc

  Procedure text6.LostFocus
  Messagebox("Ceci ferme par ex.le form de saisie et retourne au formulaire appelant !",0+32+4096,'',1500)
  Thisform.Release
  Endproc

Enddefine


pour une saisie individuelle tu peux utiliser la fonction inputbox()
local m.x
m.x=INPUTBOX(cInputPrompt [, cDialogCaption [, cDefaultValue [, nTimeout [,cTimeoutValue] [,cCancelValue]]]])



Références à consulter:
foxhelp : How to: Set Tab Order for Controls-The tab order of a form determines the sequence in which the controls are selected
when a user presses the TAB key to move through the form.
TabStop Property : Specifies whether a user can use the TAB key to move the focus to an object. Available at design time and
run time.

Articles identiques à MSDN
How to: Set Tab Order for Controls
http://msdn.microsoft.com/en-US/library/7039hzb0%28v=vs.80%29.aspx

Tab Order Dialog Box
http://msdn.microsoft.com/en-US/library/cwde6027%28v=vs.80%29.aspx

NB : pour les fenêtres (window) utilise les API SetFocus (hwnd) ,Getfocus,getAcriveWindow...

Bonne année 1995 !


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000015591
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3