ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Calcul de l'inverse d'une matrice   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

ven. 09 janvier 2015, 12h18

Vilhelm-Ion Praisach
Roumanie Roumanie

atoutfox.public.association

Re: Calcul de l'inverse d'une matrice

LOCAL lam[3,3],lainv[3,3],lnrang,lni,lnj
clear

lam[1,1]=2.0
lam[1,2]=-1.0
lam[1,3]=0.0

lam[2,1]=-1.0
lam[2,2]=2.0
lam[2,3]=-1.0

lam[3,1]=0
lam[3,2]=-1.0
lam[3,3]=2.0

FOR lni = 1 TO ALEN(m.lam,1)
?
  FOR lnj = 1 TO ALEN(m.lam,2)
    ?? m.lam[m.lni,m.lnj]
  NEXT
NEXT

IF minverse(@lam,@lainv,@lnrang)
  FOR lni = 1 TO ALEN(m.lainv,1)
  ?
    FOR lnj = 1 TO ALEN(m.lainv,2)
      ?? m.lainv[m.lni,m.lnj]
    NEXT
  NEXT
ELSE
  ? "Rang :",m.lnrang
ENDIF

************************************************************************
* Déterminer la matrice inverse si la matrice est inversible
* Déterminer le rang de la matrice si la matrice n'est pas inversible
************************************************************************
* Paramètres:
* - tamatrice  Matrice initiale
* - tainv  (sortie) matrice inverse
* - lnrang  (sortie) rang
************************************************************************
FUNCTION minverse
LPARAMETERS tamatrice,tainv,lnrang
LOCAL lnligne,lncolonne,lnlignes,lncolonnes,lnpivot,lni,lnj,lnk,lni_max,lntmp
lnlignes = ALEN(m.tamatrice,1)
lncolonnes = ALEN(m.tamatrice,2)
lnrang = MIN(m.lnlignes,m.lncolonnes)
LOCAL lamatrice[m.lnlignes,m.lncolonnes],lainv[m.lnlignes,m.lncolonnes],tainv[m.lnlignes,m.lncolonnes],lalignes[lnrang]
FOR lni = 1 TO m.lnlignes
  FOR lnj = 1 TO m.lncolonnes
    lainv[m.lni,m.lnj] = IIF(m.lni <> m.lnj , 0, 1)
  NEXT
NEXT
ACOPY(tamatrice,lamatrice)
FOR lnk = 1 TO m.lnrang
  lnpivot = ABS(m.lamatrice[m.lnk,m.lnk])
  lni_max = m.lnk
  FOR lni = 1 TO m.lnlignes
    IF ABS(m.lamatrice[m.lni,m.lnk]) > m.lnpivot
      lni_max = m.lni
      lnpivot = ABS(m.lamatrice[m.lni,m.lnk])
    ENDIF
  NEXT
  IF m.lamatrice[m.lni_max,m.lnk] = 0
    lnrang = m.lnk - 1
    RETURN .F.
  ENDIF
  lalignes[m.lnk] = m.lni_max
  FOR lni = 1 TO m.lnlignes
    IF m.lni <> m.lni_max
      FOR lnj = 1 TO m.lncolonnes
        lainv[m.lni,m.lnj] = m.lainv[m.lni,m.lnj] - m.lainv[m.lni_max,m.lnj] * m.lamatrice[m.lni,m.lnk] / m.lamatrice[m.lni_max,m.lnk]
      NEXT
      FOR lnj = m.lnk + 1 TO m.lncolonnes
        lamatrice[m.lni,m.lnj] = m.lamatrice[m.lni,m.lnj] - m.lamatrice[m.lni_max,m.lnj] * m.lamatrice[m.lni,m.lnk] / m.lamatrice[m.lni_max,m.lnk]
      NEXT
    ENDIF
  NEXT
  FOR lni = 1 TO m.lnlignes
    IF m.lni <> m.lni_max
      lamatrice[m.lni,m.lnk] = 0
    ENDIF
  NEXT
  FOR lnj = 1 TO m.lncolonnes
    lainv[m.lni_max,m.lnj] = m.lainv[m.lni_max,m.lnj] / m.lamatrice[m.lni_max,m.lnk]

    IF m.lnj <> m.lnk
      lamatrice[m.lni_max,m.lnj] = m.lamatrice[m.lni_max,m.lnj] / m.lamatrice[m.lni_max,m.lnk]
    ENDIF
  NEXT
  m.lamatrice[m.lni_max,m.lnk] = 1
NEXT
FOR lni = 1 TO m.lnlignes
  FOR lnj = 1 TO m.lncolonnes
    tainv[m.lni,m.lnj] = lainv[lalignes[m.lni],m.lnj]
  NEXT
NEXT
RETURN .T.
ENDFUNC


Journal

FoxInCloud (Th. Nivelet) pense que ce message est la bonne réponse ou qu'il est utile
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000015714
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3