ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Prévoir le gain d'un pack sur FPT   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

sam. 17 janvier 2015, 20h02
Gregory
atoutfox.public.association

Re: Prévoir le gain d'un pack sur FPT

Excellent, Francis

J'allais le faire en tenant compte du blocksize - helas trop de taf ces
derniers jours - aujourd'hui inclus



______
Gregory
______
"Francis Faure" wrote in message news:m9djv9$1qf2$1@news.niouzes.net...

Luc,

Je viens de regarder en détail la structure des fichiers mémo,
en fait pour avoir une estimation à l’octet prêt il faut prendre en compte
la taille des "Blocs" mémo (pouvant être différents selon le SET BLOCKSIZE
de la table) + prendre en compte l'entête du mémo et l'entête de chaque
blocs.

Voici le programme qui est retourne une estimation juste :

(Dans cet exemple avec une table test et un champ mémo appelé MEMO1 - pour
du réel il faut prendre en compte tous les champs mémos de la table)

* Estimation gain de la taille du fichier mémo FPT si PACK
lcTableName = "c:\temp\test" && nom de la table à analyser

if !file(m.lcTableName+".dbf")
  ? "table "+m.lcTableName+"introuvable"
  cancel
endif
if adir(laFPT, m.lcTableName+".fpt")<>1
  ? "pas de fichier mémo pour la table "+m.lcTableName
  cancel
endif

set deleted on && prendre aussi en compte la taille des enregistrements
supprimés
use (m.lcTableName) shared
? dbf()

liBlockSize=val(sys(2012)) && taille des blocs du mémo
if m.liBlockSize=0
  liBlockSize=1
endif
if m.liBlockSize<=32 && de 1 a 32 => x512
  liSizeOFMemoBlock = m.liBlockSize * 512
else
  liSizeOFMemoBlock = m.liBlockSize
endif
? "Taille du bloc mémo pour cette table=", liSizeOFMemoBlock

liSizeOfMemo=512 && && fpt header size
scan for !deleted()
  liSize=len(MEMO1) && longueur des données du mémo
  if m.liSize>0
    m.liSize = m.liSize + 8 && 4 octets de signature du bloc + 4 octets de
longueur du bloc
    liRest=m.liSizeOFMemoBlock - mod(m.liSize, m.liSizeOFMemoBlock) && ajout
des octets "perdus" du même bloc
    if m.liRest<>m.liSizeOFMemoBlock
      liSize=m.liSize + m.liRest
    endif
    liSizeOfMemo=liSizeOfMemo+liSize
  endif
endscan

? "Taille actuel du mémo :", m.laFPT[1,2]
? "Taille du mémo estimé après PACK=", m.liSizeOfMemo
? "Gain possible en Octets =", m.laFPT[1,2]-m.liSizeOfMemo
? "Gain possible en % =", (m.laFPT[1,2]-m.liSizeOfMemo)/m.laFPT[1,2]*100

* test de vérification :
use (m.lcTableName) exclu
pack
use
=adir(laFPT, m.lcTableName+".fpt")
? "Vérification algo : -------------------------------"
? "Taille mémo réel après compactage :", m.laFPT[1,2]
? "# estimé/réel", m.liSizeOfMemo-m.laFPT[1,2] && si 0 = c'est good!


Cordialement
Francis
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000015764
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3