ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: CONVERSION   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

ven. 23 janvier 2015, 09h12

Vilhelm-Ion Praisach
Roumanie Roumanie

atoutfox.public.association

Re: CONVERSION

Tu à besoin d'une fonction pour Excel ?

?getexcelcolname(25) && Y
?getexcelcolname(670) && YT
?getexcelcolname(703) && AAA
?getexcelcolname(704) && AAB
?getexcelcolname(729) && ABA
?getexcelcolname(16384) && XFD

?getexcelcolnumber('Y')
?getexcelcolnumber('YT')
?getexcelcolnumber('AAA')
?getexcelcolnumber('AAB')
?getexcelcolnumber('ABA')
?getexcelcolnumber('XFD')

FUNCTION getexcelcolname
  * Parameter
  * - lnCol    the number of column
  LPARAMETERS lnCol
  IF BETWEEN(lnCol,1,16384)
    RETURN IIF(m.lnCol <=26,[],;
        IIF(m.lnCol <=702,CHR(64 + FLOOR((m.lnCol - 1) / 26)),;
            CHR(64 + FLOOR((m.lnCol - 1 - 26) / 676))+CHR(65 + FLOOR(MOD(m.lnCol - 1 - 26,676) / 26))))+;
      CHR(65 + MOD(m.lnCol - 1,26))
  ELSE
    RETURN "-1" && error
  ENDIF
ENDFUNC

FUNCTION getexcelcolnumber
  * Parameter
  * - lcName    the column name
  LPARAMETERS lcName
  LOCAL lni
  IF !BETWEEN(LEN(m.lcName),1,3)
    RETURN -1 && error
  ENDIF
  FOR lni = 1 TO LEN(m.lcName)
    IF !ISALPHA(SUBSTR(m.lcName,m.lni,1))
      RETURN -2 && error
    ENDIF
  NEXT
  DO CASE
  CASE LEN(m.lcName) = 3
    RETURN ASC(RIGHT(m.lcName,1)) - 64 + 26 * (ASC(SUBSTR(m.lcName,2,1)) - 64) + 676 * (ASC(LEFT(m.lcName,1)) - 64)
  CASE LEN(m.lcName) = 2
    RETURN ASC(RIGHT(m.lcName,1)) - 64 + 26 * (ASC(LEFT(m.lcName,1)) - 64)
  CASE LEN(m.lcName) = 1
    RETURN ASC(m.lcName) - 64
  OTHERWISE
    RETURN -3 && ??
  ENDCASE
ENDFUNC


Permalink : http://www.atoutfox.org/nntp.asp?ID=0000015817
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3