ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Problème génration LABEL 62x29mm avec XFRX 153 et VFP en mode COM   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

lun. 02 mars 2015, 10h33

GLS
France France

atoutfox.public.association

Re: Problème génration LABEL 62x29mm avec XFRX 153 et VFP en mode COM

Francis,

le code utilisé fonctionne très bien pour toutes les impressions XFRX vers PDF que ce soit pour des REPORT ou des LABEL en mode EXE ou en mode COM.
Seul un LABEL pour une impression correctement paramétrée pour des étiquettes de 62 X 29 mm ne fonctionne pas correctement en mode COM, alors que tout se passe bien en mode EXE.

voici le code utilisé:
**** Procédure de gestion des impressions sur papier ou en PDF
* p_type, p_nom, p_tous, p_mode, p_champblobimage, p_fichiermergePDF, p_pasafficherpreview, p_tablecouranteafermer
* =THISFORM.imprime_etat("ETAT", m.cReport, .T., m.p_out, "", m.p_fichiermerge, m.p_appelformprevisualisation, .F.)
* BSW
LPARAMETERS p_1, p_2, p_3, p_4, p_5, p_6, p_7, p_8

WITH _SCREEN
  IF PCOUNT() > 4 AND VARTYPE(m.p_2) == "C" AND !EMPTY(m.p_2) AND VARTYPE(._chemin_etat) == 'C' AND DIRECTORY(._chemin_etat)
    LOCAL cType AS STRING;
      , cNom AS STRING;
      , lTous AS Boolean;
      , cMode AS STRING;
      , cTable AS STRING;
      , cEtendu AS STRING;
      , cSql AS STRING;
      , cNomComplet AS STRING;
      , cExt1 AS STRING;
      , cExt2 AS STRING;
      , cTmpEtat AS STRING;
      , cNewEtatExt1 AS STRING;
      , cNewEtatExt2 AS STRING;
      , cFileXfrx AS STRING;
      , lnRetval AS INTEGER;
      , cChampBlobImage AS STRING;
      , iLanImp AS INTEGER;
      , cRepImp AS STRING;
      , cNomPDFMerge AS STRING;
      , oMsOffice AS OBJECT;
      , oMsOfficeError AS OBJECT

    cType = IIF(EMPTY(m.p_1) OR VARTYPE(m.p_1) <> "C", "REPORT", m.p_1)
    cNom = m.p_2
    lTous = m.p_3
    cMode = m.p_4
    cNomPDFMerge = IIF(VARTYPE(m.p_6) == "C", m.p_6, "")
    cChampBlobImage = IIF(VARTYPE(m.p_5) == "C", m.p_5, "")
    cTable = ALIAS()
    cEtendu = IIF(m.lTous, "ALL", "NEXT 1")
    * Cette méthode permet d'utiliser à plusieurs un état
    * en le dupliquant dans le répertoire d'utilisation sous un nom unique
    cExt1 = IIF(m.cType = "LABEL", ".lbx", ".frx")
    cExt2 = IIF(m.cType = "LABEL", ".lbt", ".frt")
    * Initialisation de MonReportListener
    ._oRL=NEWOBJECT("MonReportlistener", "mesclasses.vcx")
    ._Xfrx=EVALUATE([xfrx("XFRX#LISTENER")])
    STORE '' TO eTablo, eGraph, eSignature
    IF USED('c_imprime')
      * Initialisation des variables eGraph et eTablo utilisées dans les états de compte rendu de résultats
      =._oRL.InitObjetTablo('c_imprime.tablo')
      eTablo = ._oRL.objettablo
      =._oRL.InitObjetGraph('c_imprime.graph')
      eGraph = ._oRL.objetgraph
    ENDIF
    IF !EMPTY(m.cChampBlobImage)
      * Initialisation de la variable eGraph utilisée dans l'état
      =._oRL.InitObjetGraph(m.cChampBlobImage)
      eGraph = ._oRL.objetgraph
    ENDIF
    * Logo par défaut
    eLogo = IIF(FILE(._image + 'logo.jpg'), ._image + 'logo.jpg', '')
    eLogoBis = IIF(FILE(._image + 'logobis.jpg'), ._image + 'logobis.jpg', '')
    * Ajout de la signature du biologiste valideur dans un état de sortie
    * Initialisation de la variable eSignature utilisée dans les états
    IF USED('v_ordonnance')
      cSql = [SELECT signature FROM operateu WHERE code_ope = ] + transformer(v_ordonnance.code_bio) + [ AND inactif = 0]
      eSignature = ICASE(;
        SqlEmet(m.cSql, 'c_rech') > 0 AND !ISNULL(c_rech.signature) AND FILE(._image + ALLTRIM(c_rech.signature));
        , ._image + ALLTRIM(c_rech.signature);
        , FILE(._image + "blanc.jpg");
        , ._image + "blanc.JPG";
        , '';
        )
      USE IN SELECT('c_rech')
      * Affectation du chemin d'accès aux REPORTs selon le site v_ordonnance.code_lab
      cRepImp = ._chemin_etat + ALLTRIM(STR(v_ordonnance.code_lab))
      IF USED('v_entete')
        * Récupération vue V_ENTETE
        =THISFORM.wViewParmSet('v_entete', 'iCle', v_ordonnance.code_lab, .T.)
        eLogo = IIF(FILE(._image + ALLTRIM(v_entete.LOGO)), ._image + ALLTRIM(v_entete.LOGO), m.eLogo)
      ENDIF
    ELSE
      * Affectation du chemin d'accès aux REPORTs selon le site par la variable globale THISFORM.code_labo
      cRepImp = ._chemin_etat + ALLTRIM(STR(m.THISFORM.code_labo))
      IF USED('v_entete')
        * Récupération vue V_ENTETE
        =THISFORM.wViewParmSet('v_entete', 'iCle', m.THISFORM.code_labo, .T.)
        eLogo = IIF(FILE(._image + ALLTRIM(v_entete.LOGO)), ._image + ALLTRIM(v_entete.LOGO), m.eLogo)
      ENDIF
    ENDIF
    * Gestion du moteur de calcul des impressions
    SET REPORTBEHAVIOR 90
    * Gestion chemin des etats selon le site permettant de gérer distinctement les imprimantes par site
    cNomComplet = IIF(DIRECTORY(m.cRepImp) AND FILE(m.cRepImp + "\" + ALLTRIM(m.cNom) + m.cExt1), m.cRepImp + "\" + ALLTRIM(m.cNom), ._chemin_etat + ALLTRIM(m.cNom))
    IF FILE(m.cNomComplet + m.cExt1)
      * Gestion multi-utilisateurs des états et étiquettes
      * Récupération nom de fichier unique
      cTmpEtat = ALLTRIM(SUBSTR(SYS(2015), 3, 10))+ TRANSFORM(_VFP.PROCESSID)
      cNewEtatExt1 = ALLTRIM(m.cTmpEtat) + m.cExt1
      cNewEtatExt2 = ALLTRIM(m.cTmpEtat) + m.cExt2
      IF FILE(m.cNewEtatExt1)
        DELETE FILE (m.cNewEtatExt1)
      ENDIF
      IF FILE(m.cNewEtatExt2)
        DELETE FILE (m.cNewEtatExt2)
      ENDIF
      * Copie de l'état dans le répertoire courant
      COPY FILE (m.cNomComplet + m.cExt1) TO (m.cNewEtatExt1)
      COPY FILE (m.cNomComplet + m.cExt2) TO (m.cNewEtatExt2)
      * Si impression déclenchée en mode forcé directement sur imprimante ou en mode LAN
      IF IIF(USED('v_entete') AND !EMPTY(v_entete.implocal), .T., IIF(!INLIST(m.cMode,'PREVIEW', 'TO PRINTER'), .F., wlLan()))
        * Impression physique sur imprimante
        IF FILE(m.cNewEtatExt1)
          SELECT (m.cTable)
          =ImprimeReportListener(m.cTmpEtat, m.cType, m.cEtendu, ._oRL, m.cMode)
        ENDIF
        IF FILE(m.cNewEtatExt1)
          DELETE FILE (m.cNewEtatExt1)
        ENDIF
        IF FILE(m.cNewEtatExt2)
          DELETE FILE (m.cNewEtatExt2)
        ENDIF
      ELSE
        * Exportation de l'impression dans un fichier (PDF  si PREVIEW ou TO PRINTER ou PDF ou CPDF sinon au format de fichier demandé) à travers XFRX
        IF FILE(m.cNewEtatExt1)
          * Transformation nom de fichier unique pour éviter les collisions d'impression simultanées de deux états de même nom
          * par deux utilisateurs différents
          cNom = m.cNom + SYS(2015)
          SELECT (m.cTable)
          cFileXfrx = ICASE(;
            m.cMode = "DOC";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".DOC";
            , m.cMode = "XL";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".XLS";
            , m.cMode = "CPDF";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".PDF";
            , m.cMode = "XML";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".XML";
            , m.cMode = "TXT";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".TXT";
            , m.cMode = "HTML";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".HTM";
            , m.cMode = "ODT";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".ODT";
            , m.cMode = "FODT";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".ODT";
            , m.cMode = "ODS";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".ODS";
            , m.cMode = "RTF";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".FRTF";
            , m.cMode = "XFF";
            , ._chemin_export + TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".XFF";
            , m.cMode = "PREVIEW";
            , ._locale + IIF(EMPTY(m.cNomPDFMerge), TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".PDF", ALLTRIM(m.cNomPDFMerge) + ".PDF");
            , m.cMode = "TO PRINTER";
            , ._locale + IIF(EMPTY(m.cNomPDFMerge), TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".PDF", ALLTRIM(m.cNomPDFMerge) + ".PDF");
            , ._chemin_export + IIF(EMPTY(m.cNomPDFMerge), TTOC(DATETIME(), 1) + ALLTRIM(m.cNom) + ".PDF", ALLTRIM(m.cNomPDFMerge) + ".PDF");
            )
          * Vérification si fichier existe déjà
          IF FILE(m.cFileXfrx) AND EMPTY(m.cNomPDFMerge)
            DELETE FILE (m.cFileXfrx)
          ENDIF
          IF m.cMode <> 'XL5'
            * Initialisation XFRX
            lnRetval = ICASE(;
              m.cMode = "DOC";
              ,  ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"DOC");
              , m.cMode = "ODT";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"ODT");
              , m.cMode = "FODT";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"FODT");
              , m.cMode = "ODS";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"ODS");
              , m.cMode = "XML";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"XML");
              , m.cMode = "TXT";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"PLAIN");
              , m.cMode = "HTML";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"HTML");
              , m.cMode = "CPDF";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"PDF");
              , m.cMode = "RTF";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"RTF");
              , m.cMode = "XFF";
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,,,"XFF");
              , ._Xfrx.SetParams(m.cFileXfrx,,.T.,,wlLan(),,"PDF",,,,IIF(EMPTY(m.cNomPDFMerge),.F.,.T.));
              )
            && si !empty(m.cNomPDFMerge) alors demande de fusion des documents dans le même fichier PDF
            IF m.lnRetval = 0
              IF m.cMode = "PDF"
                ._Xfrx.setPermissions(.T., .F., .F., .F.)
                * Inclusion police de caractères pour les caractères utilisés dans le report
                ._Xfrx.setEmbeddingType(3)
              ENDIF
              IF m.cMode = "CPDF"
                ._Xfrx.setpasswords("bvw", "bvw")
                ._Xfrx.setPermissions(.T., .F., .F., .F.)
                * Inclusion police de caractères pour les caractères utilisés dans le report
                ._Xfrx.setEmbeddingType(3)
              ENDIF
              ._Xfrx.Successor = ._oRL
              * Lancement du report
              IF m.cType = 'LABEL'
                LABEL FORM (m.cTmpEtat) OBJECT ._Xfrx &cEtendu &&NOPAGEEJECT
              ELSE
                REPORT FORM (m.cTmpEtat) OBJECT ._Xfrx &cEtendu  &&NOPAGEEJECT
              ENDIF
              ._Xfrx.finalize()
              IF !m.p_7
                * Afficher si nécessaire le form de prévisualisation en fonction du mode m.cMode et du fonctionnement LAN/WEB
                DO CASE
                  CASE !INLIST(m.cMode, 'PREVIEW', 'TO PRINTER') AND FILE(m.cFileXfrx)
                    IF !wlLan()
                      =THISFORM.wFileSaveAs(m.cFileXfrx) && download dans le navigateur internet
                    ENDIF
                  CASE INLIST(m.cMode, 'PREVIEW', 'TO PRINTER')
                    IF m.p_8 AND USED(m.cTable)
                      USE IN SELECT(m.cTable)
                    ENDIF
                    IF FILE(m.cFileXfrx)
                      =THISFORM.wForm("previsualisation.scx", wlLan(), m.cFileXfrx)
                      * Suppression du PDF temporaire de prévisualisation
                      DELETE FILE (m.cFileXfrx)
                    ENDIF
                ENDCASE
              ENDIF
            ELSE
              =STRTOFILE("Erreur initialisation XFRX N°:"+ALLTRIM(STR(m.lnRetval)),'xfrx_erreur.txt', 1)
              =ecrit_trace("Erreur initialisation XFRX N°:"+ALLTRIM(STR(m.lnRetval)), 0)
            ENDIF
          ELSE
            * Exportation directe du curseur courant en XLS par VFP
            SELECT (m.cTable)
            EXPORT TO (m.cFileXfrx) TYPE XL5
            *=XFRX_CopyToXLSX(m.cTable, m.cFileXfrx, , JUSTSTEM(m.cNom)) ²² xfrx 15.3
            IF FILE(m.cFileXfrx) AND wlWeb() && mode exportation impression XLS,etc...
              =THISFORM.wFileSaveAs(m.cFileXfrx) && download dans le navigateur internet
              * Suppression du PDF temporaire de prévisualisation
              DELETE FILE (m.cFileXfrx)
            ENDIF
          ENDIF
        ENDIF
        IF FILE(m.cNewEtatExt1)
          DELETE FILE (m.cNewEtatExt1)
        ENDIF
        IF FILE(m.cNewEtatExt2)
          DELETE FILE (m.cNewEtatExt2)
        ENDIF
      ENDIF
    ENDIF
    ._oRL = NULL
    ._Xfrx = NULL
    IF USED('v_entete')
      * Récupération vue V_ENTETE avec laboratoire courant
      =THISFORM.wViewParmSet('v_entete', 'iCle', m.THISFORM.code_labo, .T.)
    ENDIF
    * Fermeture curseur principal d'impression
    IF m.p_8 AND USED(m.cTable)
      USE IN SELECT(m.cTable)
    ENDIF
  ENDIF
ENDWITH


Amicalement
Gilles

Permalink : http://www.atoutfox.org/nntp.asp?ID=0000016037
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3