dim. 03 janvier 2016, 22h18
OlivierH
atoutfox.public.association
Re: Visual FoxPro HMAC with SHA256
Salut Mike
Merci pour ta réponse, mais le format est HMAC en Sha256
Il y a que la FLL de craig boyg qui le fait sous vfp,
je sais le faire sous .net, sais tu si on peut faire une dll .net c#
et l'utiliser en foxpro ?
Function HMAC()
http://www.sweetpotatosoftware.com/spsblog/2009/08/09/MajorVFPEncryptionUpdate.aspxSinon j'ai fini par poser ma question sur StackOverFlow
http://stackoverflow.com/questions/34581485/how-generate-authorization-in-visual-foxpro-to-connect-with-windows-azure-storagQuand on veut pousser foxpro aux dernières techno, c'est difficile de
trouver les réponses.
Est ce que dans tes applis, tu utilises les web services d'azure ou
d'amazon ?
Merci à toi
Olivier
Le 02/01/2016 03:48, Mike Gagnon a écrit :
oSHA256 = CREATEOBJECT('SHA256')
?oSHA256.Encode('The quick brown fox jumps over the lazy dog')
DEFINE CLASS SHA256 AS Custom
FUNCTION Encode (cMessage As String, iVersion As Integer) As String
LOCAL cDigest, cConst, iChunk, i
LOCAL H0, H1, H2, H3, H4, H5, H6, H7, A, ;
B, C, D, E, s0, s1, t1, t2, ch, maj
DIMENSION aWords[1]
DIMENSION W[64]
DIMENSION K[64]
IF VARTYPE(cMessage) != 'C' OR EMPTY(cMessage)
cMessage = ''
ENDIF
IF VARTYPE(iVersion) != 'N'
iVersion = 0
ENDIF
IF iVersion = 224
H0 = 0xc1059ed8
H1 = 0x367cd507
H2 = 0x3070dd17
H3 = 0xf70e5939
H4 = 0xffc00b31
H5 = 0x68581511
H6 = 0x64f98fa7
H7 = 0xbefa4fa4
ELSE
H0 = 0x6a09e667
H1 = 0xbb67ae85
H2 = 0x3c6ef372
H3 = 0xa54ff53a
H4 = 0x510e527f
H5 = 0x9b05688c
H6 = 0x1f83d9ab
H7 = 0x5be0cd19
ENDIF
cConst = '0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5,' + ;
'0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174,' + ;
'0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da,' + ;
'0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967,' + ;
'0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85,' + ;
'0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070,' + ;
'0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3,' + ;
'0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2'
ALINES(K, cConst, 1, ',')
FOR i = 1 TO 64
K[i] = INT(VAL(K[i]))
ENDFOR
this.ConvertToWordArrayMS(@aWords, cMessage)
FOR iChunk = 0 TO ALEN(aWords)-1 STEP 16
FOR i = 1 TO 16
W[i] = aWords[iChunk+i]
ENDFOR
FOR i = 17 TO 64
s0 = BITXOR(this.RightRotateInt32(W[i-15], 7), this.RightRotateInt32(W[i-15], 18), BITRSHIFT(W[i-15], 3))
s1 = BITXOR(this.RightRotateInt32(W[i-2], 17), this.RightRotateInt32(W[i-2], 19), BITRSHIFT(W[i-2], 10))
W[i] = W[i-16] + s0 + W[i-7] + s1
ENDFOR
A = H0
B = H1
C = H2
D = H3
E = H4
F = H5
G = H6
H = H7
FOR i = 1 TO 64
s0 = BITXOR(this.RightRotateInt32(A, 2), this.RightRotateInt32(A, 13), this.RightRotateInt32(A, 22))
maj = BITXOR(BITAND(A, B), BITAND(A, C), BITAND(B, C))
t2 = s0 + maj
s1 = BITXOR(this.RightRotateInt32(E, 6), this.RightRotateInt32(E, 11), this.RightRotateInt32(E, 25))
ch = BITXOR(BITAND(E, F), BITAND(BITNOT(E), G))
t1 = H + s1 + ch + K[i] + W[i]
H = G
G = F
F = E
E = D + t1
D = C
C = B
B = A
A = t1 + t2
ENDFOR
H0 = BITAND(H0 + A, 0x0ffffffff)
H1 = BITAND(H1 + B, 0x0ffffffff)
H2 = BITAND(H2 + C, 0x0ffffffff)
H3 = BITAND(H3 + D, 0x0ffffffff)
H4 = BITAND(H4 + E, 0x0ffffffff)
H5 = BITAND(H5 + F, 0x0ffffffff)
H6 = BITAND(H6 + G, 0x0ffffffff)
H7 = BITAND(H7 + H, 0x0ffffffff)
ENDFOR
cDigest = this.Int32ToHexMS(H0) + ;
this.Int32ToHexMS(H1) + ;
this.Int32ToHexMS(H2) + ;
this.Int32ToHexMS(H3) + ;
this.Int32ToHexMS(H4) + ;
this.Int32ToHexMS(H5) + ;
this.Int32ToHexMS(H6)
IF iVersion = 0
cDigest = cDigest + this.Int32ToHexMS(H7)
ENDIF
RETURN LOWER(cDigest)
FUNCTION ConvertToWordArrayMS (aArray As Variant, cString as String)
LOCAL iLen
iLen = LEN(cString)
FOR i = 1 TO (iLen - 4) STEP 4
this.Push(@aArray, BITOR( ;
BITLSHIFT(this.CharCodeAt(cString, i), 24), ;
BITLSHIFT(this.CharCodeAt(cString, i + 1), 16), ;
BITLSHIFT(this.CharCodeAt(cString, i + 2), 8), ;
this.CharCodeAt(cString, i + 3) ;
))
ENDFOR
DO CASE
CASE MOD(iLen, 4) = 0
i = 0x080000000
CASE MOD(iLen, 4) = 1
i = BITOR( ;
BITLSHIFT(this.CharCodeAt(cString, iLen), 24), ;
0x0800000 ;
)
CASE MOD(iLen, 4) = 2
i = BITOR( ;
BITLSHIFT(this.CharCodeAt(cString, iLen - 1), 24), ;
BITLSHIFT(this.charCodeAt(cString, iLen), 16), ;
0x08000 ;
)
CASE MOD(iLen, 4) = 3
i = BITOR( ;
BITLSHIFT(this.CharCodeAt(cString, iLen - 2), 24), ;
BITLSHIFT(this.CharCodeAt(cString, iLen - 1), 16), ;
BITLSHIFT(this.CharCodeAt(cString, iLen), 8), ;
0x80 ;
)
ENDCASE
this.Push(@aArray, i)
DO WHILE MOD(ALEN(aArray), 16) != 14
this.Push(@aArray, 0)
ENDDO
this.Push(@aArray, BITRSHIFT(iLen, 29))
this.Push(@aArray, BITAND(BITLSHIFT(iLen, 3), 0x0ffffffff))
RETURN
FUNCTION RightRotateInt32 (iNum, iBits)
RETURN BITOR(BITRSHIFT(iNum, iBits), BITLSHIFT(iNum, (32 - iBits)))
FUNCTION Int32ToHexMS (iVal)
LOCAL cStr, cAlpha, i
cStr = ''
cAlpha = '0123456789abcdef'
FOR i = 7 TO 0 STEP -1
cStr = cStr + SUBSTR(cAlpha, BITAND(BITRSHIFT(iVal, (i*4)), 0x0f)+1, 1)
ENDFOR
RETURN cStr
FUNCTION CharCodeAt (cString AS String, iPosition as Integer) AS Integer
LOCAL iCode
iCode = ASC(SUBSTR(cString, iPosition, 1))
RETURN iCode
FUNCTION Push (aArray, tValue)
IF !EMPTY(aArray[1])
DIMENSION aArray[ALEN(aArray)+1]
ENDIF
aArray[ALEN(aArray)] = tValue
RETURN
ENDDEFINE
>
>
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000017063