ATOUTFOX
COMMUNAUTÉ FRANCOPHONE DES PROFESSIONNELS FOXPRO
Visual FoxPro : le développement durable

Forum AtoutFox : Re: Si un fichier est supprim=c3=a9 et recr=c3=a9=c3=a9=2c Windowsrecycle la date et heure de cr=c3=a9ation=2c comment   

Sujet

rss Flux RSS des derniers messages

Vous devez vous identifier pour pouvoir poser une question ou répondre.

ven. 26 février 2016, 19h35
OlivierH
atoutfox.public.association

Re: Si un fichier est supprim=c3=a9 et recr=c3=a9=c3=a9=2c Windowsrecycle la date et heure de cr=c3=a9ation=2c comment

bonsoir

cette function change date de creat, modif, last modif

il y a marqué folder mais elle fait bien pour les fichiers



*!=============================================================!
*! Proc Qui permet de changer la date d'un fichier
*!
*! Typedate :
*! 1 && Date de création
*! 2 && Date de dernier accès
*! 3 && Date de dernier écriture
*! date_modif : 18:03
*! modifié par : olivier à cause du rajout de seconde num2buf(Sec(tDate))
*!=============================================================!
FUNCTION ChangeFolderFileDate(cFolder, tDate, TypeDate)
Local lcBuff

If Empty(TypeDate)
m.TypeDate = 0
EndIf

#DEFINE GENERIC_WRITE 0x40000000
#DEFINE GENERIC_READ 0x80000000
#DEFINE FILE_SHARE_DELETE 4
#DEFINE FILE_SHARE_READ 1
#DEFINE OPEN_EXISTING 3
#DEFINE FILE_FLAG_BACKUP_SEMANTICS 0x02000000

DECLARE INTEGER CreateFile IN kernel32;
STRING lpFileName, INTEGER dwDesiredAccess,;
INTEGER dwShareMode, INTEGER lpSecurityAttr,;
INTEGER dwCreationDisp, INTEGER dwFlagsAndAttrs,;
INTEGER hTemplateFile

Declare Integer OpenFile In kernel32;
STRING lpFileName, String @lpReOpenBuff, Integer wStyle


LOCAL hFolder

* use CreateFile for Windows NT/XP/2000 and OpenFile for Win9/Me
*!* hFolder = CreateFile(cFolder, GENERIC_WRITE+GENERIC_READ,;
*!* FILE_SHARE_READ+FILE_SHARE_DELETE, 0, OPEN_EXISTING,;
*!* FILE_FLAG_BACKUP_SEMANTICS, 0)

&& OpenFile
lcBuff = Repli(Chr(0), 250)
hFolder = OpenFile(cFolder, @lcBuff, 1)

IF hFolder = -1 && failed to open
RETURN .F. && use GetLastError to get an error code
ENDIF

DECLARE INTEGER CloseHandle IN kernel32 INTEGER hObject

DECLARE INTEGER SetFileTime IN kernel32;
INTEGER hFile, STRING lpCreationTime,;
STRING lpLastAccessTime, STRING lpLastWriteTime

DECLARE INTEGER SystemTimeToFileTime IN kernel32;
STRING lpSystemTime, STRING @lpFileTime

DECLARE INTEGER LocalFileTimeToFileTime IN kernel32;
STRING lpLocalFileTime, STRING @lpFileTime

LOCAL cSysTime, cFileTime, nResult
cFileTime = Repli(Chr(0),8)

cSysTime = num2buf(Year(tDate)) + num2buf(Month(tDate)) +;
num2buf(DOW(tDate,0)) + num2buf(Day(tDate)) +;
num2buf(Hour(tDate)) + num2buf(Minute(tDate))+
num2buf(Sec(tDate)) + Repli(Chr(0),4)

* converting SYSTEMTIME data to FILETIME
= SystemTimeToFileTime(cSysTime, @cFileTime)

* in case your local time is different from UTC
= LocalFileTimeToFileTime(cFileTime, @cFileTime)

* file handle, created, last-access, last-write
*nResult = SetFileTime(hFolder, cFileTime, 0,0)

Do case
Case TypeDate=1 && Date de création
nResult = SetFileTime(hFolder, cFileTime, 0,0)
Case TypeDate=2 && Date de dernier accès
nResult = SetFileTime(hFolder, 0, cFileTime,0)
Case TypeDate=3 && Date de dernier écriture
nResult = SetFileTime(hFolder, 0, 0,cFileTime)
Otherwise
nResult = SetFileTime(hFolder, cFileTime, cFileTime,cFileTime)
EndCase

= CloseHandle(hFolder) && important
RETURN (nResult <> 0)
ENDFUNC

FUNCTION num2buf(nValue)
RETURN Chr(MOD(m.nValue,256)) + CHR(INT(m.nValue/256))
ENDFUNC
*!=============================================================!



Olivier



Le 26/02/2016 13:33, FoxInCloud a écrit :
> Bonjour Olivier,
>
> j'ai de quoi modifier la Date et heure de modification
> en revanche pour la date de création je n'ai trouvé aucune solution avec FSO ou autre outil de scripting classique
>
> Le ven. 26 février 2016, 12h25 OlivierH a écrit :
>> Salut
>>
>> Si tu veux j'ai un code pour modifié la date / heure du fichier
>>
>> Olivier
>
>

Journal

FoxInCloud (Th. Nivelet) pense que ce message est la bonne réponse ou qu'il est utile
Permalink : http://www.atoutfox.org/nntp.asp?ID=0000017343
20 286 messages dans le forum • Liste complète des messages

www.atoutfox.org - Site de la Communauté Francophone des Professionnels FoxPro - v3.4.0 - © 2004-2026.
Cette page est générée par un composant COM+ développé en Visual FoxPro 9.0-SP2-HF3